How many users opening a BE .mdb?

Private Sub Form_Open(Cancel As Integer)
   Cancel = Not CheckBEtoForm(Me.name)
End Sub

Public Function CheckBEtoForm(ByVal FrmName As String) As Boolean
   Dim Result As Long, StrgSQL As String
   Dim ComputerUserLoginName As String, ComputerName As String
   Dim MacAddress As String
   
   Result = Nz(DMax("[LogID]", "[LogTable]", "[FormAccessed]='" & FrmName & "' AND [UserLogOutDateTime] IS NULL"), 0)
   If Result > 0 Then
      MsgBox "The Back-End Database is already in use for this Form. Please try again later."
      CheckBEtoForm = False: Exit Function
   Else
      ComputerUserLoginName = VBA.Environ("USERNAME")
      ComputerName = VBA.Environ("COMPUTERNAME")
      MacAddress = GetMACAddress("-")
      StrgSQL = "INSERT INTO LogTable (FormAccessed,UserName,ComputerName," & _
                "MACAddress,UserLogInDateTime) VALUES ('" & FrmName & "','" & _
                ComputerUserLoginName & "','" & ComputerName & "','" & _
                MacAddress & "',#" & Now() & "#);"
      CurrentDb.Execute StrgSQL
      CheckBEtoForm = True
   End If
End Function

Option Explicit

'===========================================================
'This section of code was originally writen by: Randy Birch
'===========================================================

Private Const NCBASTAT As Long = &H33
Private Const NCBNAMSZ As Long = 16
Private Const HEAP_ZERO_MEMORY As Long = &H8
Private Const HEAP_GENERATE_EXCEPTIONS As Long = &H4
Private Const NCBRESET As Long = &H32

Private Type NET_CONTROL_BLOCK  'NCB
   ncb_command    As Byte
   ncb_retcode    As Byte
   ncb_lsn        As Byte
   ncb_num        As Byte
   ncb_buffer     As Long
   ncb_length     As Integer
   ncb_callname   As String * NCBNAMSZ
   ncb_name       As String * NCBNAMSZ
   ncb_rto        As Byte
   ncb_sto        As Byte
   ncb_post       As Long
   ncb_lana_num   As Byte
   ncb_cmd_cplt   As Byte
   ncb_reserve(9) As Byte 'Reserved, must be 0
   ncb_event      As Long
End Type

Private Type ADAPTER_STATUS
   adapter_address(5) As Byte
   rev_major         As Byte
   reserved0         As Byte
   adapter_type      As Byte
   rev_minor         As Byte
   duration          As Integer
   frmr_recv         As Integer
   frmr_xmit         As Integer
   iframe_recv_err   As Integer
   xmit_aborts       As Integer
   xmit_success      As Long
   recv_success      As Long
   iframe_xmit_err   As Integer
   recv_buff_unavail As Integer
   t1_timeouts       As Integer
   ti_timeouts       As Integer
   Reserved1         As Long
   free_ncbs         As Integer
   max_cfg_ncbs      As Integer
   max_ncbs          As Integer
   xmit_buf_unavail  As Integer
   max_dgram_size    As Integer
   pending_sess      As Integer
   max_cfg_sess      As Integer
   max_sess          As Integer
   max_sess_pkt_size As Integer
   name_count        As Integer
End Type
   
Private Type NAME_BUFFER
   name        As String * NCBNAMSZ
   name_num    As Integer
   name_flags  As Integer
End Type

Private Type ASTAT
   adapt          As ADAPTER_STATUS
   NameBuff(30)   As NAME_BUFFER
End Type

Private Declare Function Netbios Lib "netapi32" _
   (pncb As NET_CONTROL_BLOCK) As Byte
     
Private Declare Sub CopyMemory Lib "kernel32" _
   Alias "RtlMoveMemory" _
  (hpvDest As Any, ByVal _
   hpvSource As Long, ByVal _
   cbCopy As Long)
     
Private Declare Function GetProcessHeap Lib "kernel32" () As Long

Private Declare Function HeapAlloc Lib "kernel32" _
  (ByVal hHeap As Long, _
   ByVal dwFlags As Long, _
   ByVal dwBytes As Long) As Long
     
Private Declare Function HeapFree Lib "kernel32" _
  (ByVal hHeap As Long, _
   ByVal dwFlags As Long, _
   lpMem As Any) As Long

Public Function GetMACAddress(sDelimiter As String) As String
  'retrieve the MAC Address for the network controller
  'installed, returning a formatted string
   Dim tmp As String
   Dim pASTAT As Long
   Dim NCB As NET_CONTROL_BLOCK
   Dim AST As ASTAT
   Dim cnt As Long

  'The IBM NetBIOS 3.0 specifications defines four basic
  'NetBIOS environments under the NCBRESET command. Win32
  'follows the OS/2 Dynamic Link Routine (DLR) environment.
  'This means that the first NCB issued by an application
  'must be a NCBRESET, with the exception of NCBENUM.
  'The Windows NT implementation differs from the IBM
  'NetBIOS 3.0 specifications in the NCB_CALLNAME field.
   NCB.ncb_command = NCBRESET
   Call Netbios(NCB)
   
  'To get the Media Access Control (MAC) address for an
  'ethernet adapter programmatically, use the Netbios()
  'NCBASTAT command and provide a "*" as the name in the
  'NCB.ncb_CallName field (in a 16-chr string).
   NCB.ncb_callname = "*               "
   NCB.ncb_command = NCBASTAT
   
  'For machines with multiple network adapters you need to
  'enumerate the LANA numbers and perform the NCBASTAT
  'command on each. Even when you have a single network
  'adapter, it is a good idea to enumerate valid LANA numbers
  'first and perform the NCBASTAT on one of the valid LANA
  'numbers. It is considered bad programming to hardcode the
  'LANA number to 0 (see the comments section below).
   NCB.ncb_lana_num = 0
   NCB.ncb_length = Len(AST)
   
   pASTAT = HeapAlloc(GetProcessHeap(), _
                      HEAP_GENERATE_EXCEPTIONS Or _
                      HEAP_ZERO_MEMORY, _
                      NCB.ncb_length)
   If pASTAT <> 0 Then
      NCB.ncb_buffer = pASTAT
      Call Netbios(NCB)
      CopyMemory AST, NCB.ncb_buffer, Len(AST)
     'convert the byte array to a string
      GetMACAddress = MakeMacAddress(AST.adapt.adapter_address(), sDelimiter)
      HeapFree GetProcessHeap(), 0, pASTAT
    Else
      Debug.Print "memory allocation failed!"
      Exit Function
   End If
End Function


Private Function MakeMacAddress(b() As Byte, sDelim As String) As String
   Dim cnt As Long
   Dim buff As String
   
   On Local Error GoTo MakeMac_error
 
  'so far, MAC addresses are
  'exactly 6 segments in size (0-5)
   If UBound(b) = 5 Then
      'concatenate the first five values
     'together and separate with the
     'delimiter char
      For cnt = 0 To 4
         buff = buff & Right$("00" & Hex(b(cnt)), 2) & sDelim
      Next
      'and append the last value
      buff = buff & Right$("00" & Hex(b(5)), 2)
    End If  'UBound(b)
   MakeMacAddress = buff
   
MakeMac_exit:
   Exit Function
   
MakeMac_error:
   MakeMacAddress = "(error building MAC address)"
   Resume MakeMac_exit
End Function

Private Sub Form_Unload(Cancel As Integer)
   Call FormLogOut
End Sub

Public Sub FormLogOut(ByVal FrmName As String)
   Dim Result As Long, StrgSQL As String
   Dim ComputerUserLoginName As String, ComputerName As String
   Dim MacAddress As String
   
   ComputerUserLoginName = VBA.Environ("USERNAME")
   ComputerName = VBA.Environ("COMPUTERNAME")
   MacAddress = GetMACAddress("-")
   
   Result = DLookup("[LogID]", "[LogTable]", "[FormAccessed]='" & FrmName & _
                 "' AND [UserName]='" & ComputerUserLoginName & _
                 "' AND [ComputerName]='" & ComputerName & "' AND [MACAddress]='" & _
                 MacAddress & "' AND [UserLogOutDateTime] IS NULL")
   
   StrgSQL = "UPDATE [LogTable] SET [UserLogOutDateTime]=#" & Now() & _
             "# WHERE [LogID]=" & Result & ";"
                
   CurrentDb.Execute StrgSQL
End Sub

Function CountConnectionInUse()
'If first time install data path wil not exist in registry
If GetSysDataPath = False Then
    Exit Function
End If
'check to see if the target database exists.
If Dir(SysDataPath & "\icatsdata.MDB") = "" Then
    MsgBox "Cannot find the source database." & vbCrLf & vbCrLf & "Unable to connect to " & UCase(SysDataPath) & "\icatsdata.MDB. Please check that the file exists in the specified location. " & vbCrLf & vbCrLf & IIf(Left(SysDataPath, 1) <> "C", "Check network connection via My Computer.", "") & vbCrLf & vbCrLf & "Application will terminate once you click the Ok button.", vbCritical + vbOKOnly, "Cannot detect database"
    End ' teminate application
End If
    
Dim BumsOnSeats As Integer
Dim szMaxUsers As Integer
    szMaxUsers = 15
    
    Dim cn As ADODB.Connection
    Set cn = New ADODB.Connection
    ' Open the connection
    With cn
      .Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
         "Data Source=" & SysDataPath & "\icatsdata.mdb"
    End With
    'You have to take off 1 user as you are part of the count
    BumsOnSeats = CountUsers(cn) - 1
    Set cn = Nothing
    If BumsOnSeats >= szMaxUsers Then
        If szMaxUsers > 1 Then
            MsgBox "There are aready " & szMaxUsers & " users logged into the application." & vbCrLf & vbCrLf & "Please wait while another user logs out before attempting to log in again.", vbExclamation + vbOKOnly, "Maximum number of concurrent users reached."
        Else
            MsgBox "There is aready 1 user logged into the application." & vbCrLf & vbCrLf & "Please wait while this user logs out before attempting to log in again.", vbExclamation + vbOKOnly, "Maximum number of concurrent users reached."
        End If
        
        End ' teminate application
    End If
    
        
    
   
End Function

Function CountUsers(cn As ADODB.Connection)
    Dim rs          As ADODB.Recordset


    ' The user roster is exposed as a provider-specific schema rowset
    ' in the Jet 4.0 OLE DB provider.  You have to use a GUID to
    ' reference the schema, as provider-specific schemas are not
    ' listed in ADO's type library for schema rowsets

    Set rs = cn.OpenSchema(adSchemaProviderSpecific, _
    , "{947bb102-5d43-11d1-bdbf-00c04fb92675}")

    CountUsers = 0
    With rs
        Do Until .EOF
            CountUsers = CountUsers + 1
            .MoveNext
        Loop
    End With
     
    rs.Close
    Set rs = Nothing


End Function