Mail Merge - Dynamic subject line?

[RossWindows]

I know in mail merge you can specify what you want in the subject line, but that causes the subject line to be the same for all records sent in that batch.

Is there a way to have the subject line change for each record to include the "PO#" that is included in the <<PO Number>> field in the body of each record?

[Tanya]

Your question is too vague. Why don't you upload a copy of what you are trying to work with?

[hutchinsfairy]

For anyone else looking for the answer Try:

Dim WithEvents wdapp As Application
Dim EMAIL_SUBJECT As String
Dim FIRST_RECORD As Boolean


Private Sub Document_Open()

    Set wdapp = Application
    ThisDocument.MailMerge.ShowWizard 1
   
End Sub

Private Sub Document_Close()

    Set wdapp = Nothing
    
End Sub


Private Sub wdapp_MailMergeBeforeRecordMerge(ByVal Doc As Document, Cancel As Boolean)
    Dim i As Integer
    
    With ActiveDocument.MailMerge
    
        If FIRST_RECORD = True Then 
            EMAIL_SUBJECT = .MailSubject
            FIRST_RECORD = False
        Else .MailSubject = EMAIL_SUBJECT
        End If

        i = .DataSource.DataFields.Count
        
        Do While i > 0
            .MailSubject = Replace(.MailSubject, "<" & .DataSource.DataFields(i).Name & ">", .DataSource.DataFields(i).Value, , , vbTextCompare)
            i = i - 1
        Loop

    End With
    
     
End Sub


Private Sub wdapp_MailMergeBeforeMerge(ByVal Doc As Document, ByVal StartRecord As Long, ByVal EndRecord As Long, Cancel As Boolean)

    FIRST_RECORD = True
    
End Sub

Private Sub wdapp_MailMergeAfterMerge(ByVal Doc As Document, ByVal DocResult As Document)

    ActiveDocument.MailMerge.MailSubject = EMAIL_SUBJECT
     
End Sub

This will intercept Mail Merge requests and parse the subject line for merge fields. Just put chevrons round the name of the Merge Field.

e.g. "Reference Request for <Applicant_Name>"

You can find Merge Field names by using them in your document and pressing Alt+F9.

This only works if you initiate the Mail Merge via the task pane and not if you use the Toolbar button.

[RossWindows]

Now that is a great 1st post! I'll definately be hanging on to that.

[hutchinsfairy]

Thanks!

Bear in mind that it will error if you try to merge to another destination (printer etc)

You can wrap the code within the subs with:

If ActiveDocument.MailMerge.Destination = wdSendToEmail Then

End if

to avoid this.

[philtulip]

I can't seem to get this to work.

I currently have an e-mail merge which I am creating through Word.

I have created a new Macro and pasted the code you have provided but I get the following error when running the macro (at what point do I run it? am I doing this correctly?) - "Compile Error: Syntax error"

Sorry for sounding a bit of a novice but if I can get this to work it would be excellent.

A bit of background - I need the subject line to read "<ID> notice" where ID is a merge field from an excel list.

Thanks!

[hutchinsfairy]

With your letter open press Alt+F11 and double click "ThisDocument" in the window that opens (it should be near the top left in a pane called "Project - Project").

Paste the entire code into the blank pane that opens and save. Close the Visual Basic Editor and the Word document and re-open the word document.

Run the merge from the wizard that should appear to the right of the document.

Generally the ID of the merge field is the Excel column title with underscores instead of spaces.

Hope that's some help

[philtulip]

Originally Posted by hutchinsfairy

Generally the ID of the merge field is the Excel column title with underscores instead of spaces.

So when I get to the stage of entering the subject line, if the merge field I wanted to insert was "StudentID" i'd enter <_StudentID_> ?

Thanks in advance.

[hutchinsfairy]

If the column title in Excel is "StudentID" then try "<StudentID>" (without quotes).
If you know what the MergeField is called (which can be different from the column title in Excel) then just add the chevrons.

[philtulip]

I have tried your suggestion and it has been unsuccessful.

I have copy/pasted your code exactly how you have said (I don't need to replace any of this code with my own?) and I have also put <ID> (my merge field in excel AND word) in the subject line but this does not work.

Does it matter that my file has been saved as .docm? does it need to be saved as another file type?

Cheers.

[philtulip]

Never mind, it does work! It's because my macros were disabled! Hurrah!

[meazcc]

This was great! Thank you so much!

[mikeo1313]

I pasted the code and its not working for me in word 2007, but, I'm also not using the task pane, just the ribbon.

please help!. I'm using an excel data souce and want to use a certain column for the subject of the word-outlook mail merge

[RossWindows]

Well, I know for sure that it works with Office 2003. That could be the source of the problem, but not necessarily so...

What steps have you taken so far? and have you tried anything else without luck? Try to be as specific as possible.

[mikeo1313]

I created my message, added my fields, saved my doc as a macro enabled file, saved the macro code in post exactly as in msowrdocs->thisdocument. enabled all macros via office->word options -> trust center,,,, used both <<sub>> & <sub> and nothing.