Gantt Chart Woes (1 Viewer)

Sub populate_Output()
' loops through Input tab and extracts data to Output tab

Dim wb_Input As Worksheet: Set wb_Input = ThisWorkbook.Sheets("Input")
Dim wb_Output As Worksheet: Set wb_Output = ThisWorkbook.Sheets("Output")
    ' references to Input and Output tabs

Dim str_LastCellA As String: str_LastCellA = "Error"  ' value of prior row's A cell
Dim str_ThisCellA As String: str_ThisCellA = "Error"  ' value of current row's A cell

Dim str_Acct As String: str_Acct = "Error"          ' Account value to use for Output tab record
Dim str_Customer As String: str_Customer = "Error"  ' Customer value to use for Output tab record

Dim int_InputRow: int_InputRow = 1                  ' what row of Input to read from
Dim int_OutputRow: int_OutputRow = 2                ' what row of Output to write to

Dim int_ColStart: int_ColStart = 1                  ' what Input column to start with when copying a row of data
Dim int_ColEnd: int_ColEnd = 11                     ' what Input column to end with when copying a row of data

Dim counter_i: counter_i = int_ColStart             ' counter, to loop through columns to copy


'   **********      Above:  Variables         **********
'   **********      Below   Processing        **********


Do While str_LastCellA <> "End"
    ' loops through Input rows extracting data to Output tab
    
    str_ThisCellA = wb_Input.Cells(int_InputRow, 1)
    
    If str_ThisCellA = "" Then
    ' found blank row, sets Customer and Account to error values
        str_Customer = "Error"
        str_Acct = "Error"
        End If
     
    If IsDate(str_ThisCellA) Then
    ' on a row that needs to be extracted to Output
 
        wb_Output.Cells(int_OutputRow, 1) = str_Acct
        wb_Output.Cells(int_OutputRow, 2) = str_Customer
    ' puts Account and Customer values into Output row
        
        For counter_i = int_ColStart To int_ColEnd
    ' copies selected columns from Input to Output
            wb_Output.Cells(int_OutputRow, counter_i + 2) = wb_Input.Cells(int_InputRow, counter_i)
        Next
         
        int_OutputRow = int_OutputRow + 1
    ' moves Output data go to next row to write on
         End If

    If Left(str_ThisCellA, 4) = "Acct" Then
    ' on an account row, will get Account and Customer data
        str_Acct = Mid(str_ThisCellA, 8, 9)
        str_Customer = Mid(str_ThisCellA, InStr(str_ThisCellA, "-") + 2)
    End If
    
    int_InputRow = int_InputRow + 1
    ' moves Input tab to next row
  
    If (str_LastCellA = "") And (str_ThisCellA = "") Then str_LastCellA = "End" Else str_LastCellA = str_ThisCellA
   ' if 2 blank A cells in a row, process is done
Loop


End Sub