bold line in auto email code

dark11984 · Sep 23, 2010

Hi,
I'm trying to make a line of text in an email bold. I've searched heaps of other threads and found lots of info on it but still no luck.

I've tried .fontbold = true and .bold = true.

I want to make the line that contains SigFname and SigSName bold and all other texts normal.

Code:

MyMail.Body = "Attached is the SSO Monhtly report for " & [PrevMth] & "." & vbNewLine & vbNewLine & _
            "Regards," & vbNewLine & vbNewLine & _
            [SigFname] & " " & [SigSName] & vbNewLine & _
            [sigPosition] & vbNewLine & _
            [SigDepartment] & " | " & [SigCompany] & vbNewLine & _
            "P:" & " " & [SigPhone] & " | M: " & [SigMobile] & " | F: " & [SigFax] & vbNewLine & _
            "E:" & " " & [SigEmail]

Cheers,

The_Doc_Man · Sep 23, 2010

It is going to depend on your e-mail editor, which in turn depends on your version of Office. Starting with Access 2007, I believe, you can have Word as your editor for e-mail. Then it would be possible to select that line and embolden it.

Since I've never actually tried that, I'm not up on it, but it is theoretically possible.

If you are on something before Office 2007, I'm not so sure because I don't think Word was the editor of choice in that case.

ChrisO · Sep 23, 2010

Something to try: -

Code:

Sub TestIt()

    With CreateObject("Outlook.Application").CreateItem(0)
        .Subject = "My Subject"
        
        ' Set body format to HTML
        .BodyFormat = 2
        
        ' Format the message
        .HTMLBody = _
            "<html>" & _
                "Dear Sir" & "<br><br>" & _
                "<b>" & _
                    "Name: " & "Sam Spade" & "<br>" & _
                    "Position:" & "Chief Cook and Bottle Washer" & "<br><br>" & _
                "</b>" & _
                "Normal body text starts here." & "<br><br>" & _
            "</html>"

        ' Display Email
        .Display
    End With

End Sub

Chris.

dark11984 · Sep 23, 2010

Well just wrote my first html code... Thanks Chris.

Only problem is it changed to Times New Roman font, any idea to how to get the font to Arial?

ChrisO · Sep 23, 2010

Code:

Sub TestIt()

    With CreateObject("Outlook.Application").CreateItem(0)
        .Subject = "My Subject"
        
        ' Set body format to HTML
        .BodyFormat = 2
        
        ' Format the message
        .HTMLBody = _
            "<html>" & _
                "Dear Sir" & "<br><br>" & _
                "<b>" & _
                    "Name: " & "Sam Spade" & "<br>" & _
                    "Position:" & "Chief Cook and Bottle Washer" & "<br><br>" & _
                    "<font face='Arial'" & "<br>" & _
                        "Name: " & "Sam Spade" & "<br>" & _
                        "Position:" & "Chief Cook and Bottle Washer" & "<br><br>" & _
                    "</font>" & _
                    "<font face='Monotype Corsiva'" & "<br>" & _
                        "Name: " & "Sam Spade" & "<br>" & _
                        "Position:" & "Chief Cook and Bottle Washer" & "<br><br>" & _
                    "</font>" & _
                "</b>" & _
                "Normal body text starts here." & "<br><br>" & _
            "</html>"

        ' Display Email
        .Display
    End With

End Sub

dark11984 · Sep 23, 2010

Thanks - that helped out heaps.

bold line in auto email code

dark11984

Registered User.

The_Doc_Man

Immoderate Moderator

ChrisO

Registered User.

dark11984

Registered User.

ChrisO

Registered User.

dark11984

Registered User.

Similar threads

Users who are viewing this thread