Concatenate won't group

[ErinL]

Hi everyone - I am having problems with using a concatenate function in my database. I am using Allen Browne's sample:

Public Function ConcatRelated(strField As String, _
strTable As String, _
Optional strWhere As String, _
Optional strOrderBy As String, _
Optional strSeparator = ", ") As Variant
On Error GoTo Err_Handler
'Purpose: Generate a concatenated string of related records.
'Return: String variant, or Null if no matches.
'Arguments: strField = name of field to get results from and concatenate.
' strTable = name of a table or query.
' strWhere = WHERE clause to choose the right values.
' strOrderBy = ORDER BY clause, for sorting the values.
' strSeparator = characters to use between the concatenated values.
'Notes: 1. Use square brackets around field/table names with spaces or odd characters.
' 2. strField can be a Multi-valued field (A2007 and later), but strOrderBy cannot.
' 3. Nulls are omitted, zero-length strings (ZLSs) are returned as ZLSs.
' 4. Returning more than 255 characters to a recordset triggers this Access bug:
' http://allenbrowne.com/bug-16.html
Dim rs As DAO.Recordset 'Related records
Dim rsMV As DAO.Recordset 'Multi-valued field recordset
Dim strSql As String 'SQL statement
Dim strOut As String 'Output string to concatenate to.
Dim lngLen As Long 'Length of string.
Dim bIsMultiValue As Boolean 'Flag if strField is a multi-valued field.

'Initialize to Null
ConcatRelated = Null

'Build SQL string, and get the records.
strSql = "SELECT " & strField & " FROM " & strTable
If strWhere <> vbNullString Then
strSql = strSql & " WHERE " & strWhere
End If
If strOrderBy <> vbNullString Then
strSql = strSql & " ORDER BY " & strOrderBy
End If
Set rs = DBEngine(0)(0).OpenRecordset(strSql, dbOpenDynaset)
'Determine if the requested field is multi-valued (Type is above 100.)
bIsMultiValue = (rs(0).Type > 100)

'Loop through the matching records
Do While Not rs.EOF
If bIsMultiValue Then
'For multi-valued field, loop through the values
Set rsMV = rs(0).Value
Do While Not rsMV.EOF
If Not IsNull(rsMV(0)) Then
strOut = strOut & rsMV(0) & strSeparator
End If
rsMV.MoveNext
Loop
Set rsMV = Nothing
ElseIf Not IsNull(rs(0)) Then
strOut = strOut & rs(0) & strSeparator
End If
rs.MoveNext
Loop
rs.Close

'Return the string without the trailing separator.
lngLen = Len(strOut) - Len(strSeparator)
If lngLen > 0 Then
ConcatRelated = Left(strOut, lngLen)
End If
Exit_Handler:
'Clean up
Set rsMV = Nothing
Set rs = Nothing
Exit Function
Err_Handler:
MsgBox "Error " & Err.Number & ": " & Err.Description, vbExclamation, "ConcatRelated()"
Resume Exit_Handler
End Function

I call it in the query as follows:

SELECT tblMeetingAttendees.MeetingDate, tblMeetingAttendees.LeanIdeaNumber, ConcatRelated("FLName","tblMeetingAttendees","MeetingDate = " & [MeetingDate] And "LeanIdeaNumber = " & [LeanIdeaNumber]) AS Attendees
FROM tblMeetingAttendees
GROUP BY tblMeetingAttendees.MeetingDate, tblMeetingAttendees.LeanIdeaNumber, ConcatRelated("FLName","tblMeetingAttendees","MeetingDate = " & [MeetingDate] And "LeanIdeaNumber = " & [LeanIdeaNumber]);

The table shows:

LeanIdeaNumber MeetingDate FLName
4 3/4/12 John Doe
4 3/4/12 Jane Davis
4 3/5/12 Pam Smith
4 3/5/12 Paul Johnson

I would like the results to look like this:

LeanIdeaNumber MeetingDate FLName
4 3/4/12 John Doe, Jane Davis
4 3/5/12 Pam Smith, Paul Johnson

Instead, the results look like this:

LeanIdeaNumber MeetingDate FLName
4 3/4/12 John Doe, Jane Davis, Pam Smith, Paul Johnson
4 3/5/12 John Doe, Jane Davis, Pam Smith, Paul Johnson

It ignores the meeting date field and combines all the names like they all attended both meetings.

I have tried to find my mistake but am at a very beginner level when it comes to code and am hoping someone will help me.

Thank you so much.

 

[Beetle]

Looks like you have a couple of minor problems in your where clause for the ConcatRelated function. First, the And operator should be inside the quotes. Also, you will probably need to add some date delimiters. Try this (changes are in red).

SELECT tblMeetingAttendees.MeetingDate, tblMeetingAttendees.LeanIdeaNumber, ConcatRelated("FLName","tblMeetingAttendees","MeetingDate = #" & [MeetingDate] & "# And LeanIdeaNumber = " & [LeanIdeaNumber]) AS Attendees
FROM tblMeetingAttendees
GROUP BY tblMeetingAttendees.MeetingDate, tblMeetingAttendees.LeanIdeaNumber, ConcatRelated("FLName","tblMeetingAttendees","MeetingDate = #" & [MeetingDate] & "# And LeanIdeaNumber = " & [LeanIdeaNumber]);

(the double quote that is currently right before LeanIdeaNumber = needs to be moved to the left of the second date delimter (#))

 

[ErinL]

Oh yes!! That works exactly how I want it to!

Thank you so much!

Trying to learn to write code on my own as I go is very frustrating because I don't know all the little details and those little details make or break it. This forum has been a great tool for me and I appreciate you and everyone who take the time to help people like me.

Thanks again!