FileDialog - New Files

[Tieval]

I am trying to use FileDialog with the code below
to export a file. The code refuses to enter new file names and gives a message "file not found".

Any clues would be most welcome.

Private Sub Command6_Click()
'Requires reference to Microsoft Office 12.0 Object Library.
 
   Dim fDialog As Office.FileDialog
   Dim varFile As Variant
 
   'Clear listbox contents.
   Me.FileList.RowSource = ""
 
   'Set up the File Dialog.
   Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
   With fDialog
      'Allow user to make multiple selections in dialog box.
      .AllowMultiSelect = True
             
      'Set the title of the dialog box.
      .Title = "Export to"
 
      'Clear out the current filters, and add our own.
      .Filters.Clear
      .Filters.Add "Excel Files", "*.XLSX"
 
      'Show the dialog box. If the .Show method returns True, the
      'user picked at least one file. If the .Show method returns
      'False, the user clicked Cancel.
      If .Show = True Then
         'Loop through each file selected and add it to the list box.
         For Each varFile In .SelectedItems
            Me.FileList.AddItem varFile
         Next
      Else
         MsgBox "You clicked Cancel in the file dialog box."
      End If
   End With
End Sub

 

[Tieval]

Fixed:

Private Sub Command6_Click()
'Requires reference to Microsoft Office 12.0 Object Library.
 
   Dim fDialog As Office.FileDialog
   Dim varFile As Variant
 
   'Clear listbox contents.
   Me.FileList.RowSource = ""
 
   'Set up the File Dialog.
   Set fDialog = Application.FileDialog(msoFileDialogSaveAs)
   With fDialog
      'Allow user to make multiple selections in dialog box.
      .AllowMultiSelect = True
             
      'Set the title of the dialog box.
      .Title = "Export to"
 
      'Clear out the current filters, and add our own.
      '.Filters.Clear
      '.Filters.Add "Excel Files", "*.XLSX"
 
      'Show the dialog box. If the .Show method returns True, the
      'user picked at least one file. If the .Show method returns
      'False, the user clicked Cancel.
      If .Show = True Then
         'Loop through each file selected and add it to the list box.
         For Each varFile In .SelectedItems
            Me.FileList.AddItem varFile
         Next
      Else
         MsgBox "You clicked Cancel in the file dialog box."
      End If
   End With
End Sub