Solved Hide/show new record in continuous form (1 Viewer)

[Kayleigh]

Hi there,
Have a continuous form which shows all previous records fine. Since I don't want the new records line displayed, I have allowAdditions = false in the onCurrent event. However the command button to add a new record is always bringing up an error that it can't go to the specified record. Here is my code - what have I done wrong?

Private Sub cmdAddNew_Click()
Me.AllowAdditions = True
DoCmd.GoToRecord , , acNewRec
If IsNothing(Me.fldRStaffID) Then
Me.fldRStaffID = Forms!frmLogin!cmbstaff
Me.fldRDate = Now
End If
End Sub

When I miss out the doCmd.GoToRecord...it opens a new record but misses the if loop.
Any suggestions?

 

[theDBguy]

Hi. I'm just a little confused. Where is your button located? I don't understand this part.

When I miss out the doCmd.GoToRecord...it opens a new record but misses the if loop.

Is it "opening" another form? Have you considered using the Default Value property?

 

[arnelgp]

If IsNothing(Me.fldRStaffID) Then

can you use IsNull() instead?

 

[Kayleigh]

This button is on the same form. It should go to a new record on continuous form and add the default data as specified in code.
But when try changing to isNull still getting this error message...

 

[arnelgp]

i see you are resetting AllowAdditions on the Current event of the Form.
add another form-variable:

Option Compare Database
Option Explicit

'arnelgp
Dim bolPass As Boolean

Private Sub Form_Current()
    If Not bolPass Then
        Me.AllowAdditions = False
    End If
    bolPass = False
End Sub

Private Sub cmdAddNew_Click()
'arnelgp
'prevent current from resetting
'the Form's AllowAddtions property
bolPass = True
'
Me.AllowAdditions = True
DoCmd.GoToRecord , , acNewRec
If IsNull(Me.fldRStaffID) Then
    Me.fldRStaffID = Forms!frmLogin!cmbstaff
    Me.fldRDate = Now
End If
End Sub

 

[Kayleigh]

Works very well. Thank you!

 

[gemma-the-husky]

Do you mean the asterisk button in the navigation keys is enabled? I would have thought if allowadditions is false, then the asterisk would be disabled also.