searching another database

[dark11984]

I have used a sample database from the net and modified to my requirements to make a search form to search my database(enquirydb_pmcpn.mdb) for any enquiries that have been entered. I've got it working fine but I now want to extend it to search another database(enquirydb_pnashl.mdb) too. I have added a check box onto the form and if checked i want it to search enquirydb_pnashl.mdb, if unchecked only search enquirydb_pnmcpn.mdb. Here is the current code i am using:

Private Sub cmdFilter_Click()
'Purpose: Build up the criteria string form the non-blank search boxes, and apply to the form's Filter.
'Notes: 1. We tack " AND " on the end of each condition so you can easily add more search boxes; _
we remove the trailing " AND " at the end.
' 2. The date range works like this: _
Both dates = only dates between (both inclusive. _
Start date only = all dates from this one onwards; _
End date only = all dates up to (and including this one).
Dim strWhere As String 'The criteria string.
Dim lngLen As Long 'Length of the criteria string to append to.
Const conJetDate = "\#mm\/dd\/yyyy\#" 'The format expected for dates in a JET query string.

'***********************************************************************
'Look at each search box, and build up the criteria string from the non-blank ones.
'***********************************************************************
'Text field example. Use quotes around the value in the string.

If Not IsNull(Me.TxtFilterVendorsPart) Then
strWhere = strWhere & "([VendorsPart] = """ & Me.TxtFilterVendorsPart & """) AND "
End If

'Another text field example. Use Like to find anywhere in the field.
If Not IsNull(Me.txtFilterSalesperson) Then
strWhere = strWhere & "([EMPLOYEE ID] = """ & Me.txtFilterSalesperson & """) AND "
End If

'Another text field example. Use Like to find anywhere in the field.
If Not IsNull(Me.txtfilterItemDesc) Then
strWhere = strWhere & "([ItemDesc] Like ""*" & Me.txtfilterItemDesc & "*"") AND "
End If

'Another text field example. Use Like to find anywhere in the field.
If Not IsNull(Me.txtFilterVendor) Then
strWhere = strWhere & "([Vendor] Like ""*" & Me.txtFilterVendor & "*"") AND "
End If

'Date field example. Use the format string to add the # delimiters and get the right international format.
If Not IsNull(Me.txtStartDate) Then
strWhere = strWhere & "([Date] >= " & Format(Me.txtStartDate, conJetDate) & ") AND "
End If

'Another date field example. Use "less than the next day" since this field has times as well as dates.
If Not IsNull(Me.txtEndDate) Then 'Less than the next day.
strWhere = strWhere & "([Date] < " & Format(Me.txtEndDate + 1, conJetDate) & ") AND "
End If

'***********************************************************************
'Chop off the trailing " AND ", and use the string as the form's Filter.
'***********************************************************************
'See if the string has more than 5 characters (a trailng " AND ") to remove.
lngLen = Len(strWhere) - 5
If lngLen <= 0 Then 'Nah: there was nothing in the string.
MsgBox "No criteria", vbInformation, "Nothing to do."
Else 'Yep: there is something there, so remove the " AND " at the end.
strWhere = Left$(strWhere, lngLen)
'For debugging, remove the leading quote on the next line. Prints to Immediate Window (Ctrl+G).
'Debug.Print strWhere

'Finally, apply the string as the form's Filter.
Me.Filter = strWhere
Me.FilterOn = True
End If
End Sub

Thanks.

 

[Guus2005]

To search thru a table in another database use a query like this:

select * from table1 in 'c:\temp\anotherdatabase.mdb'

Enjoy!

 

[DCrake]

Just to extend the response from Guus2005 any tables that reside in the front end or are linked tables in the front end can be addressed as belonging to the CurrentDb().

Any tables that are not explicity linked can also be referred to. In other words you do not need to link a table from a different mdb to be able to access it.

For resident and linked tables use:

Dim Rs As DAO.Recordset

Set Rs = CurrentDb.OpenRecordset("YourTableOrQueryName")

For objects in a "Closed" database:

Dim Dbs As DAO.Database
Dim Rst As DAO.Recordset

Set Dbs = OpenDatabase("YourDatabaseName")
Set Rst = Dbs.OpenRecordset("YourTableOrQueryName")

Remember to use Rst.Close and Dbs.Close along with Set Rst = Nothing and Set Dbs = Nothing to reset the links and remove any referrences at the conculsion of you code/application.

CodeMaster: