Solved Working with a PowerPoint table (1 Viewer)

[The Rev]

Good morning,

I have a PowerPoint slide that has a table as one of the elements on the slide. I need to select the table and then replace the string "<Co Name>" with my stored variable of CompanyName. I don't know how to call the table and loop through the table cells for that string. Here's what I have thus far that doesn't seem to be working...

Set CurSlide = objPresentation.Slides(13).Select()
Dim t As Table
Dim tRow As Long, iCol As Long
Dim tText As TextRange
Dim tTemp As TextRange
With t
For tRow = 1 To .Rows.Count
For tCol = 1 To .Columns.Count
Set tText = .Cell(tRow, tCol).Shape.TextFrame.TextRange
Do
Set tTemp = tText.Replace("<Co Name>", CompanyName, , WholeWords, MatchCase)
Loop While Not tTemp Is Nothing
Next tCol
Next tRow
End With

 

[The Rev]

Still no idea why this isn't working...

 

[Minty]

You aren't actually setting your table variable to anything... And before that you would need to then set the table as a shape object.

Dim oSh as Shape

Set oSh = CurSlide.Shapes("YourTableName")
Set t = oSh.Table
With t ....

 

[The Rev]

Still no luck. Here's the table by itself on a slide.

 

[Minty]

Why not use the code I provided before with a tiny alteration?

Sub ChangeText()
        
    Dim t As Table
    Dim tRow As Long, tCol As Long
    Dim tText As TextRange
    Dim tTemp As TextRange
    Dim sTemplate As String
    Dim objPPT As Object
    Dim oSh As Object
    Dim CompanyName As String
    Dim FindWord As String
    Dim iWords As Long
    
    
    FindWord = "<Co Name>"
    
    sTemplate = "C:\AccessForums\Schedule.pptx" ' Change to suit your file
    
    CompanyName = "M$oft Corp"
    
    Set objPPT = CreateObject("PowerPoint.Application")
      
    Set ppPres = objPPT.Presentations.Open(sTemplate)
    
    With ppPres.Slides(1)
        Set oSh = .Shapes("Table5")
        Set t = oSh.Table
    
        With t
            For tRow = 1 To .Rows.Count
                For tCol = 1 To .Columns.Count
                    Debug.Print tRow, tCol
                    Set tText = .Cell(tRow, tCol).Shape.TextFrame.TextRange.Find(FindWord)
                    
                    If Not (tText Is Nothing) Then 'if something is found
                        tText.Text = CompanyName      'then replace it
                        iWords = iWords + 1
                    End If
                    
               Next tCol
            Next tRow
        End With
    End With
    
End Sub

 

[The Rev]

I tinkered and finally got it to work.

Dim t As Table
Dim tRow As Long
Dim iCol As Long
Dim oSh As Shape
Dim tText As String

For Each objShape In objPresentation.Slides(13).Shapes
    Set t = oSh.Table

    With t
        For tRow = 1 To objShape.Table.Rows.Count
            For tCol = 1 To objShape.Table.Columns.Count
                objShape.Table.Cell(tRow, tCol).Shape.TextFrame.TextRange = Replace(objShape.Table.Cell(tRow, tCol).Shape.TextFrame.TextRange, "<Co Name>", CompanyName)
            Next tCol
        Next tRow
    End With
Next objShape