Error 438 - Object doesn't support this property or method (1 Viewer)

[JohnPapa]

I have an Access FE and an SQL Express BE.

I tried using the following code which works fine in an Access13 FE and ACE BE.

I call the SendEmail fumction using

Dim varDum As Variant
    varDum = SendEmail("MyEmailExample.com", "", "", True, "", Me.strPath)

The SendEmail function

Function SendEmail(strTo As String, strSubject As String, strBody As String, bEdit As Boolean, _
                   Optional strBCC As Variant, Optional AttachmentPath As Variant)
'Send Email using late binding to avoid reference issues
   Dim objOutlook As Object
   Dim objOutlookMsg As Object
   Dim objOutlookRecip As Object
   Dim objOutlookAttach As Object
   Dim i As Integer
   Const olMailItem = 0

   On Error GoTo ErrorMsgs

   Set objOutlook = CreateObject("Outlook.Application")

   Set objOutlookMsg = objOutlook.CreateItem(olMailItem)
   With objOutlookMsg

      .Subject = strSubject
      .Body = strBody
      .Importance = 2
    
      ' Add attachments to the message.
      If Not IsMissing(AttachmentPath) Then
        If IsArray(AttachmentPath) Then
           For i = LBound(AttachmentPath) To UBound(AttachmentPath) - 1
              If AttachmentPath(i) <> "" And AttachmentPath(i) <> "False" Then
                Set objOutlookAttach = .Attachments.Add(AttachmentPath(i))
              End If
           Next i
        Else
            If AttachmentPath <> "" Then
                '***********************************************************************
                Set objOutlookAttach = .Attachments.Add(AttachmentPath)  '**************
                '***********************************************************************
            End If
        End If
      End If

      If bEdit Then
        .display
      Else
        .Send
      End If
   End With

   Set objOutlookMsg = Nothing
   Set objOutlook = Nothing
   Set objOutlookRecip = Nothing
   Set objOutlookAttach = Nothing

ErrorMsgs:
      MsgBox Err.Number & " - " & Err.Description
      Exit Function
End Function

I receive the following error, on execution of the following line

Set objOutlookAttach = .Attachments.Add(AttachmentPath)

 

[Josef P.]

Probably MailItem.Attachments.Add does not know what to do with a textbox reference. ;-)

varDum = SendEmail("MyEmailExample.com", "", "", True, "", Me.strPath)
vs.
varDum = SendEmail("MyEmailExample.com", "", "", True, "", Me.strPath.Value)

/edit:
[OT]

If AttachmentPath(i) <> "" ...

When is a string (in VBA) smaller than ""?
=>

If AttachmentPath(i) > "" ...

 

[JohnPapa]

JosefP it did it, many thanks.

My previous code has been working for many years (ACCESS13 FE and ACE BE). Do you know why this is the case?

 

[arnelgp]

also, your code is only sending "less than 1" attachment due to this:

 For i = LBound(AttachmentPath) To UBound(AttachmentPath) - 1

you should not deduct 1 since you are using Ubound().

 

[cheekybuddha]

Josef and Arnel have suggested possible solutions which affect different parts of the code than you specify.

If those solutions don't solve your problem, then try and debug a little further. Add some code like:

' ...
            If AttachmentPath <> "" Then
                Debug.Print "AttachmentPath: ", Nz(AttachmentPath, "NULL")
                '***********************************************************************
                Set objOutlookAttach = .Attachments.Add(AttachmentPath)  '**************
                '***********************************************************************
            End If
' ...

Then run and check the Immediate Window (Crtr+G) for any output, and post back here.

 

[JohnPapa]

Josef and Arnel have suggested possible solutions which affect different parts of the code than you specify.

If those solutions don't solve your problem, then try and debug a little further. Add some code like:

' ...
            If AttachmentPath <> "" Then
                Debug.Print "AttachmentPath: ", Nz(AttachmentPath, "NULL")
                '***********************************************************************
                Set objOutlookAttach = .Attachments.Add(AttachmentPath)  '**************
                '***********************************************************************
            End If
' ...

Then run and check the Immediate Window (Crtr+G) for any output, and post back here.

As mentioned in #2 the problem was solved with the following replacement

varDum = SendEmail("MyEmailExample.com", "", "", True, "", Me.strPath)
vs.
varDum = SendEmail("MyEmailExample.com", "", "", True, "", Me.strPath.Value)

I had checked "AttachmentPath" and it arrived not Null

 

[JohnPapa]

also, your code is only sending "less than 1" attachment due to this:

 For i = LBound(AttachmentPath) To UBound(AttachmentPath) - 1

you should not deduct 1 since you are using Ubound().

You are correct, I wonder why was this the case. I will check. Thanks.

 

[cheekybuddha]

As mentioned in #2 the problem was solved with the following replacement

Missed that!

 

[JohnPapa]

Missed that!

Many thanks for your input though