Simple OR logic wont work

[johnkrytus]

Why won't this work?
It works with without the 'or' but with it, it just gets ignored.

If rs!TermsID <> (4 Or 3) Then

 

[Alansidman]

Try this:

If rs!TermsID <> 4 Or rs!Terms <> 3 Then

 

[johnkrytus]

Tried that first.....no go.
Here's the whole thing:

Private Sub b_PrintWorkOrder_Click()
    Me.Requery
    Dim CreditCheckQry As String
    Dim TermsDatedQry As String
    Dim strCompany_id As Integer
    Dim stlinkCriteria As String

    strCompany_id = [Forms]![People_Enter]![People_Enter_Assignments].Form!company_id
    CreditCheckQry = "SELECT TermsID FROM companies WHERE company_id = " & strCompany_id
    TermsDatedQry = "SELECT TermsDate FROM companies WHERE company_id = " & strCompany_id
    
    Dim dbCreditCheck As dao.Database
    Dim rsCreditCheck As dao.Recordset
    Set dbCreditCheck = CurrentDb()
    Set rsCreditCheck = dbCreditCheck.OpenRecordset(CreditCheckQry, dbOpenDynaset)
    
    Dim dbTermsDated As dao.Database
    Dim rsTermsDated As dao.Recordset
    Set dbTermsDated = CurrentDb()
    Set rsTermsDated = dbTermsDated.OpenRecordset(TermsDatedQry, dbOpenDynaset)
    
    If rsTermsDated!TermsDate <> "" Then
        If rsCreditCheck!TermsID <> 3 Or rsCreditCheck!TermsID <> 4 Then
            stlinkCriteria = "[EntryId]=" & [Forms]![People_Enter]![People_Enter_Assignments].Form!EntryId
            DoCmd.OpenReport "WorkOrder", acPreview, , stlinkCriteria
            DoCmd.Close acForm, "People_Enter"
        Else
          MsgBox "This account appears to have terms, however it is not open"
        End If
    Else
      MsgBox "It appears that there are no terms on file"
    End If
    
    rsCreditCheck.Close
    rsTermsDated.Close
    Set rsTermsDated = Nothing
    Set dbTermsDated = Nothing
    Set rsCreditCheck = Nothing
    Set dbCreditCheck = Nothing
End Sub

 

[Alansidman]

try changing the "or" to an "and"

 

[johnkrytus]

I tried it ..because you suggested it. But no, an AND does not work. How could it? It would be impossible to ever have that condition.

 

[plog]

It would be impossible to ever have that condition.

Incorrect. It would be impossible to not meet your criteria:

If X <> 3 Or X <> 4

Run these 3 values for X:

X=2-> True because X<>3
X=3-> True because X<>4
X=4-> True because X<>3

Your statement will always evaluate to true. Now test Alan's:

If X <> 3 AND X <> 4
X=2-> True because X<>3 is true AND X<>4 is true
X=3-> False because X<>3 is False
X=4-> False because X<>4 is False

AND means all conditions are met, OR means just one.

 

[johnkrytus]

It hurts my pride (just a little) to be wrong on something such as this––but of course you are right....and nonetheless it feels good to have solved it.

I switched it around

    If rsTermsDated!TermsDate <> "" Then
        If rsCreditCheck!TermsID = 4 Or rsCreditCheck!TermsID = 3 Or rsCreditCheck!TermsID = 14 Then
            MsgBox "This account appears to have terms, however it is not an open account"
        Else
            stlinkCriteria = "[EntryId]=" & [Forms]![People_Enter]![People_Enter_Assignments].Form!EntryId
            DoCmd.OpenReport "WorkOrder", acPreview, , stlinkCriteria
            DoCmd.Close acForm, "People_Enter"
        End If
    Else
      MsgBox "It appears that there are no terms on file"
    End If

Thank you for your help