VBA query to check form value chosen

[tezread]

I was wondering what syntax is used to refer to a variable value chosen in a combo box of a form?

I am using Allen Browns concatrelated function to list results from a query but I am trying to limit results to a specific date. I cannot use Forms]![frmViewAgenda]![Choosedate] in the query I refer to as the function falls over so I need to adapt the function so it works dynamically in VBA to check what date was chosen in the form

this is the code from Allen:

Public Function ConcatRelated(strField As String, _
    strTable As String, _
    Optional strWhere As String, _
    Optional strOrderBy As String, _
    Optional strSeparator = ", ") As Variant
On Error GoTo Err_Handler
    'Purpose:   Generate a concatenated string of related records.
    'Return:    String variant, or Null if no matches.
    'Arguments: strField = name of field to get results from and concatenate.
    '           strTable = name of a table or query.
    '           strWhere = WHERE clause to choose the right values.
    '           strOrderBy = ORDER BY clause, for sorting the values.
    '           strSeparator = characters to use between the concatenated values.
    'Notes:     1. Use square brackets around field/table names with spaces or odd characters.
    '           2. strField can be a Multi-valued field (A2007 and later), but strOrderBy cannot.
    '           3. Nulls are omitted, zero-length strings (ZLSs) are returned as ZLSs.
    '           4. Returning more than 255 characters to a recordset triggers this Access bug:
    '               [URL]http://allenbrowne.com/bug-16.html[/URL]
    Dim rs As DAO.Recordset         'Related records
    Dim rsMV As DAO.Recordset       'Multi-valued field recordset
    Dim strSql As String            'SQL statement
    Dim strOut As String            'Output string to concatenate to.
    Dim lngLen As Long              'Length of string.
    Dim bIsMultiValue As Boolean    'Flag if strField is a multi-valued field.
    
    'Initialize to Null
    ConcatRelated = Null
    
    'Build SQL string, and get the records.
    strSql = "SELECT " & strField & " FROM " & strTable
    If strWhere <> vbNullString Then
        strSql = strSql & " WHERE " & strWhere
    End If
    If strOrderBy <> vbNullString Then
        strSql = strSql & " ORDER BY " & strOrderBy
    End If
    Set rs = DBEngine(0)(0).OpenRecordset(strSql, dbOpenDynaset)
    'Determine if the requested field is multi-valued (Type is above 100.)
    bIsMultiValue = (rs(0).Type > 100)
    
    'Loop through the matching records
    Do While Not rs.EOF
        If bIsMultiValue Then
            'For multi-valued field, loop through the values
            Set rsMV = rs(0).Value
            Do While Not rsMV.EOF
                If Not IsNull(rsMV(0)) Then
                    strOut = strOut & rsMV(0) & strSeparator
                End If
                rsMV.MoveNext
            Loop
            Set rsMV = Nothing
        ElseIf Not IsNull(rs(0)) Then
            strOut = strOut & rs(0) & strSeparator
        End If
        rs.MoveNext
    Loop
    rs.Close
    
    'Return the string without the trailing separator.
    lngLen = Len(strOut) - Len(strSeparator)
    If lngLen > 0 Then
        ConcatRelated = Left(strOut, lngLen)
    End If
Exit_Handler:
    'Clean up
    Set rsMV = Nothing
    Set rs = Nothing
    Exit Function
Err_Handler:
    MsgBox "Error " & Err.Number & ": " & Err.Description, vbExclamation, "ConcatRelated()"
    Resume Exit_Handler
End Function

 

[dragofly]

What do you mean by falls over. I usually just use the combobox.value function and convert as necessary.

 

[tezread]

check out the attachment and you will see what I mean.
open frmviewagenda form, pick a date and run report

on the report is a text field where the names of people are supposed to be listed for that meeting date

The concatrelated function falls over if you specify a parameter in ther query - it falls over as the arguments don't match up in

 

[jal]

check out the attachment and you will see what I mean.
open frmviewagenda form, pick a date and run report

on the report is a text field where the names of people are supposed to be listed for that meeting date

The concatrelated function falls over if you specify a parameter in ther query - it falls over as the arguments don't match up in

I think your assessment is correct. That is to say, when running an SQL command from VBA, you cannot use the name of the cbo directly in the SQL (and likewise you cannot run a saved query that does so). Thus if the saved query is:

SELECT....WHERE frmCustomer!cboCustomer = ....

it won't work because VBA, oddly enough, won't recognize "frmCustomer!cboCustomer" as a cbo. One solution is to build the SQL string yourself (add # signs around dates). Maybe something like this:

Dim SQL as string
SQL = "SELECT tblMeeting.MeetingID, tblMeeting.MeetingDate, tblApology.Apology FROM tblMeeting INNER JOIN tblApology ON tblMeeting.MeetingID = tblApology.MeetingID WHERE tblMeeting.MeetingDate =#" & [Forms]![frmViewAgenda]![ChooseDate] & "#"

and then pass that SQL into ConcatRelat