Help need in setting up Call to Open/Save dialog box

[method]

Hi every body . I found this code that supposed to allow me browse for .mdb file and select it. But unfortunely i could not set it up. could an expert help me set this up in access 2000. Furthermore how i can refrence the loaded .mdb file when ever i want to use
it instead of current db in vba.Thanks

***************** Code Start **************
'This code was originally written by Ken Getz.
'It is not to be altered or distributed,
'except as part of an application.
'You are free to use it in any application,
'provided the copyright notice is left unchanged.
'
' Code courtesy of:
' Microsoft Access 95 How-To
' Ken Getz and Paul Litwin
' Waite Group Press, 1996

Type tagOPENFILENAME
    lStructSize As Long
    hwndOwner As Long
    hInstance As Long
    strFilter As String
    strCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    strFile As String
    nMaxFile As Long
    strFileTitle As String
    nMaxFileTitle As Long
    strInitialDir As String
    strTitle As String
    Flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    strDefExt As String
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type

Declare Function aht_apiGetOpenFileName Lib "comdlg32.dll" _
    Alias "GetOpenFileNameA" (OFN As tagOPENFILENAME) As Boolean

Declare Function aht_apiGetSaveFileName Lib "comdlg32.dll" _
    Alias "GetSaveFileNameA" (OFN As tagOPENFILENAME) As Boolean
Declare Function CommDlgExtendedError Lib "comdlg32.dll" () As Long

Global Const ahtOFN_READONLY = &H1
Global Const ahtOFN_OVERWRITEPROMPT = &H2
Global Const ahtOFN_HIDEREADONLY = &H4
Global Const ahtOFN_NOCHANGEDIR = &H8
Global Const ahtOFN_SHOWHELP = &H10
' You won't use these.
'Global Const ahtOFN_ENABLEHOOK = &H20
'Global Const ahtOFN_ENABLETEMPLATE = &H40
'Global Const ahtOFN_ENABLETEMPLATEHANDLE = &H80
Global Const ahtOFN_NOVALIDATE = &H100
Global Const ahtOFN_ALLOWMULTISELECT = &H200
Global Const ahtOFN_EXTENSIONDIFFERENT = &H400
Global Const ahtOFN_PATHMUSTEXIST = &H800
Global Const ahtOFN_FILEMUSTEXIST = &H1000
Global Const ahtOFN_CREATEPROMPT = &H2000
Global Const ahtOFN_SHAREAWARE = &H4000
Global Const ahtOFN_NOREADONLYRETURN = &H8000
Global Const ahtOFN_NOTESTFILECREATE = &H10000
Global Const ahtOFN_NONETWORKBUTTON = &H20000
Global Const ahtOFN_NOLONGNAMES = &H40000
' New for Windows 95
Global Const ahtOFN_EXPLORER = &H80000
Global Const ahtOFN_NODEREFERENCELINKS = &H100000
Global Const ahtOFN_LONGNAMES = &H200000

Function TestIt()
    Dim strFilter As String
    Dim lngFlags As Long
    strFilter = ahtAddFilterItem(strFilter, "Access Files (*.mda, *.mdb)", _
                    "*.MDA;*.MDB")
    strFilter = ahtAddFilterItem(strFilter, "dBASE Files (*.dbf)", "*.DBF")
    strFilter = ahtAddFilterItem(strFilter, "Text Files (*.txt)", "*.TXT")
    strFilter = ahtAddFilterItem(strFilter, "All Files (*.*)", "*.*")
    MsgBox "You selected: " & ahtCommonFileOpenSave(InitialDir:="C:\", _
        Filter:=strFilter, FilterIndex:=3, Flags:=lngFlags, _
        DialogTitle:="Hello! Open Me!")
    ' Since you passed in a variable for lngFlags,
    ' the function places the output flags value in the variable.
    Debug.Print Hex(lngFlags)
End Function

Function GetOpenFile(Optional varDirectory As Variant, _
    Optional varTitleForDialog As Variant) As Variant
' Here's an example that gets an Access database name.
Dim strFilter As String
Dim lngFlags As Long
Dim varFileName As Variant
' Specify that the chosen file must already exist,
' don't change directories when you're done
' Also, don't bother displaying
' the read-only box. It'll only confuse people.
    lngFlags = ahtOFN_FILEMUSTEXIST Or _
                ahtOFN_HIDEREADONLY Or ahtOFN_NOCHANGEDIR
    If IsMissing(varDirectory) Then
        varDirectory = ""
    End If
    If IsMissing(varTitleForDialog) Then
        varTitleForDialog = ""
    End If

    ' Define the filter string and allocate space in the "c"
    ' string Duplicate this line with changes as necessary for
    ' more file templates.
    strFilter = ahtAddFilterItem(strFilter, _
                "Access (*.mdb)", "*.MDB;*.MDA")
    ' Now actually call to get the file name.
    varFileName = ahtCommonFileOpenSave( _
                    OpenFile:=True, _
                    InitialDir:=varDirectory, _
                    Filter:=strFilter, _
                    Flags:=lngFlags, _
                    DialogTitle:=varTitleForDialog)
    If Not IsNull(varFileName) Then
        varFileName = TrimNull(varFileName)
    End If
    GetOpenFile = varFileName
End Function

Function ahtCommonFileOpenSave( _
            Optional ByRef Flags As Variant, _
            Optional ByVal InitialDir As Variant, _
            Optional ByVal Filter As Variant, _
            Optional ByVal FilterIndex As Variant, _
            Optional ByVal DefaultExt As Variant, _
            Optional ByVal FileName As Variant, _
            Optional ByVal DialogTitle As Variant, _
            Optional ByVal hwnd As Variant, _
            Optional ByVal OpenFile As Variant) As Variant
' This is the entry point you'll use to call the common
' file open/save dialog. The parameters are listed
' below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem. See examples.
' FilterIndex: 1-based integer indicating which filter
' set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one.
' Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename
Dim OFN As tagOPENFILENAME
Dim strFileName As String
Dim strFileTitle As String
Dim fResult As Boolean
    ' Give the dialog a caption title.
    If IsMissing(InitialDir) Then InitialDir = CurDir
    If IsMissing(Filter) Then Filter = ""
    If IsMissing(FilterIndex) Then FilterIndex = 1
    If IsMissing(Flags) Then Flags = 0&
    If IsMissing(DefaultExt) Then DefaultExt = ""
    If IsMissing(FileName) Then FileName = ""
    If IsMissing(DialogTitle) Then DialogTitle = ""
    If IsMissing(hwnd) Then hwnd = Application.hWndAccessApp
    If IsMissing(OpenFile) Then OpenFile = True
    ' Allocate string space for the returned strings.
    strFileName = Left(FileName & String(256, 0), 256)
    strFileTitle = String(256, 0)
    ' Set up the data structure before you call the function
    With OFN
        .lStructSize = Len(OFN)
        .hwndOwner = hwnd
        .strFilter = Filter
        .nFilterIndex = FilterIndex
        .strFile = strFileName
        .nMaxFile = Len(strFileName)
        .strFileTitle = strFileTitle
        .nMaxFileTitle = Len(strFileTitle)
        .strTitle = DialogTitle
        .Flags = Flags
        .strDefExt = DefaultExt
        .strInitialDir = InitialDir
        ' Didn't think most people would want to deal with
        ' these options.
        .hInstance = 0
        '.strCustomFilter = ""
        '.nMaxCustFilter = 0
        .lpfnHook = 0
        'New for NT 4.0
        .strCustomFilter = String(255, 0)
        .nMaxCustFilter = 255
    End With
    ' This will pass the desired data structure to the
    ' Windows API, which will in turn it uses to display
    ' the Open/Save As Dialog.
    If OpenFile Then
        fResult = aht_apiGetOpenFileName(OFN)
    Else
        fResult = aht_apiGetSaveFileName(OFN)
    End If

    ' The function call filled in the strFileTitle member
    ' of the structure. You'll have to write special code
    ' to retrieve that if you're interested.
    If fResult Then
        ' You might care to check the Flags member of the
        ' structure to get information about the chosen file.
        ' In this example, if you bothered to pass in a
        ' value for Flags, we'll fill it in with the outgoing
        ' Flags value.
        If Not IsMissing(Flags) Then Flags = OFN.Flags
        ahtCommonFileOpenSave = TrimNull(OFN.strFile)
    Else
        ahtCommonFileOpenSave = vbNullString
    End If
End Function

Function ahtAddFilterItem(strFilter As String, _
    strDescription As String, Optional varItem As Variant) As String
' Tack a new chunk onto the file filter.
' That is, take the old value, stick onto it the description,
' (like "Databases"), a null character, the skeleton
' (like "*.mdb;*.mda") and a final null character.

    If IsMissing(varItem) Then varItem = "*.*"
    ahtAddFilterItem = strFilter & _
                strDescription & vbNullChar & _
                varItem & vbNullChar
End Function

Private Function TrimNull(ByVal strItem As String) As String
Dim intPos As Integer
    intPos = InStr(strItem, vbNullChar)
    If intPos > 0 Then
        TrimNull = Left(strItem, intPos - 1)
    Else
        TrimNull = strItem
    End If
End Function
'************** Code End *****************

 

[modest]

Put the code you listed above into a module. In your own function (probably a button's click event) post something like the following code.

Dim strFilter As String
Dim strFile   As String

strFilter = ahtAddFilterItem(strFilter, "Access Database(*.mdb)", "*.MDB")
strFile = ahtCommonFileOpenSave(InitialDir:=CurrentDb.Name, Filter:=strFilter, OpenFile:=True, DialogTitle:="Select Database To Open")

If you want to reference the database like the CurrentDb, you'll have to use DAO or ADO (if strFile holds the path of the database you want to open):

Dim wrk     As DAO.Workspace
Dim db      As DAO.Database
Dim dbOther As DAO.Database

Set wrk = DBEngine(0)
Set db = CurrentDb
Set dbOther = wrk.OpenDatabase(strFile)

 

[tony007]

Many many thanks for u reply. i can make the load the db but now i want to use the current loaded db for this code. Here is the code that i want to use the curent loaded db rather then current db.I be happy if u tell me what parts do i need to change. Is there a global solution since i got many codes similer to this that i want to change only a few things on the top rather changing many things.Thanks

Option Compare Database

Private Sub Command0_Click()
Dim strFilter As String
Dim strFile As String

strFilter = ahtAddFilterItem(strFilter, "Access Database(*.mdb)", "*.MDB")
strFile = ahtCommonFileOpenSave(InitialDir:=CurrentDb.Name, Filter:=strFilter, openfile:=True, DialogTitle:="Select Database To Open")
End Sub
Function FieldName()
Dim strField As String
For Each TableDef In CurrentDb.TableDefs
'''this if statment remove the system feilds
 If Left(TableDef.Name, 4) <> "Msys" Then
   For Each Field In TableDef.Fields
      strField = Field.Name
      '''MsgBox.Field.Name
      List3.RowSource = List3.RowSource + strField + ";"
    Next
  End If
Next
End Function

Private Sub Command1_Click()
FieldName
End Sub

 

[modest]

You should send the database object itself to make it more universal:

Function FieldName(Db As DAO.Database)
    Dim strField As String

    For Each TblDef In Db.TableDefs
      'Remove the system fields
        If Left(TblDef.Name, 4) <> "Msys" Then
           For Each Field In TblDef.Fields
              strField = Field.Name
              List3.RowSource = List3.RowSource + strField + ";"
           Next
        End If
    Next
End Function

I renamed "TableDef" to "TblDef" because TableDef is a datatype. Using keywords will cause errors. You would call the function like so:

Private Sub Command1_Click()
    Dim db As DAO.Database
    Set db = CurrentDb    
    Call FieldName(Db)
End Sub

Also, notice how much easier it is to read my code. This is why formatting is important.

 

[tony007]

Many thanks for u reply. In my form a got a button that is loading external mdb. then i got another button that on click should display all the fields inside the list box. When i click notthing happens. I want to run the fieldname code for the external loaded db not current db. I be happy if u help me fix this .Thanks

Option Compare Database

Private Sub Command0_Click()
Dim strFilter As String
Dim strFile As String

strFilter = ahtAddFilterItem(strFilter, "Access Database(*.mdb)", "*.MDB")
strFile = ahtCommonFileOpenSave(InitialDir:=CurrentDb.Name, Filter:=strFilter, openfile:=True, DialogTitle:="Select Database To Open")
End Sub
Function FieldName(Db As DAO.Database)
Dim strField As String
For Each TableDef In CurrentDb.TableDefs
'''this if statment remove the system feilds
 If Left(TableDef.Name, 4) <> "Msys" Then
   For Each Field In TableDef.Fields
      strField = Field.Name
      '''MsgBox.Field.Name
      List3.RowSource = List3.RowSource + strField + ";"
    Next
  End If
Next
End Function

Private Sub Command1_Click()
'''FieldName

    Dim Db As DAO.Database
    Set Db = CurrentDb
    Call FieldName(Db)

End Sub

 

[modest]

Before I answer I request 2 things:

1) Clean up your code... your functions are running into each other, there are misspelled words, and it's just not leveled all that neatly.

2) You did not make all the changes I had suggested. If you expect me to reply to your post, you must first thoroughly look at what I had posted and make the necessary updates.

 

[accessman2]

Global Const ahtOFN_HIDEREADONLY = &H4


What's that means &H4?

I don't understand.
Please let me know, thanks.

 

[ghudson]

Global Const ahtOFN_HIDEREADONLY = &H4

What's that means &H4?

I don't understand.

Please let me know, thanks.

AccessBoy,

Of course you do not understand. You have yet to attempt to try and learn for yourself. When are you going to stop wasting resources and learn how to search for yourself!!! I just googled for "IDEREADONLY" and only found over one hundred links with the answer to your lazy question.

No, I am not going to post the answer for you will have to search and find it yourself if it means that much to you.