Print Screen into Image file (1 Viewer)

Status
Not open for further replies.

pr2-eugin

Super Moderator
Local time
Today, 10:24
Joined
Nov 30, 2011
Messages
8,494
Hello everyone,

The following functionality has been very important to me.

I have been put in situations where I had troubles trying to see what my users are doing differently that makes some weird errors to throw up. In spite of me asking them sincerely, they just either do not know how to explain or they do not want to look stupid, so they are not honest enough. Sometime, I cannot provide support at all time, some errors could happen when I am on my day off or after I have left home for the day. So I had to see what they are doing, so I had to actively capture the error state (Even though I had a ErrorLogger to handle, some errors made no sense).

So I had been looking around the internet, in search for a function to Caputre the Active screen and then save it as a Image file. The Clipboard function whihc is available in VB is not available on VBA, so none of the methods actually helped. Some that seems to work, did not work on a 64-bit machine.

The following module consists of contributions that I had collected (and modified) from several sources. They were all bits and pieces, here and there; that I had to put together. Example, I found the code for 'PrintScreen' on one website and 'Converting Clipboard to Image' in another forum, so I wrote one complete module to do all of them in one single go..

I am sure this will help some.. :)

BTW, the code has been written to be used in both 32-bit and 64-bit versions. I did some research on DLL files, the file olepro32.dll which was used in Creating the image file, is not "technically" available in 64-bit. The file to be used is oleaut32.dll.

The following code goes into a new module. Give it a name save and compile for any errors.

Code:
[COLOR=Green]'***********************************************************************************************
'   * Please leave any Trademarks or Credits in place.
'   *
'   * ACKNOWLEDGEMENT TO CONTRIBUTORS :
'   *       STEPHEN BULLEN, 15 November 1998 - Original PastPicture code
'   *       G HUDSON, 5 April 2010 - Pause Function
'   *       LUTZ GENTKOW, 23 July 2011 - Alt + PrtScrn
'   *       PAUL FRANCIS, 11 April 2013 - Putting all pieces together, bridging the 32 bit and 64 bit version.
[/COLOR][COLOR=Green]'   *       CHRIS O, 12 April 2013 - Code suggestion to work on older versions of Access[/COLOR].[COLOR=Green]
'   *
'   * DESCRIPTION: Creates a standard Picture object from whatever is on the clipboard.
'   *              This object is then saved to a location on the disc. Please note, this
'   *              can also be assigned to (for example) and Image control on a userform.
'   *
'   * The code requires a reference to the "OLE Automation" type library.
'   *
'   * The code in this module has been derived from a number of sources
'   * discovered on MSDN, Access World Forum, VBForums.
'   *
'   * To use it, just copy this module into your project, then you can use:
'   * SaveClip2Bit("C:\Pics\Sample.bmp")
'   * to save this to a location on the Disc.
'   * (Or)
'   * Set ImageControl.Image = PastePicture
'   * to paste a picture of whatever is on the clipboard into a standard image control.
'   *
'   * PROCEDURES:
'   *   PastePicture  :   The entry point for 'Setting' the Image
'   *   CreatePicture :   Private function to convert a bitmap or metafile handle to an OLE reference
'   *   fnOLEError    :   Get the error text for an OLE error code
'   *   SaveClip2Bit  :   The entry point for 'Saving' the Image, calls for PastePicture
'   *   AltPrintScreen:   Performs the automation of Alt + PrtScrn, for getting the Active Window.
'   *   Pause         :   Makes the program wait, to make sure proper screen capture takes place.
'**************************************************************************************************[/COLOR]

Option Explicit
Option Compare Text

[COLOR=Green]'Declare a UDT to store a GUID for the IPicture OLE Interface[/COLOR]
Private Type GUID
    Data1 As Long
    Data2 As Integer
    Data3 As Integer
    Data4(0 To 7) As Byte
End Type

[COLOR=Green]'Declare a UDT to store the bitmap information[/COLOR]
Private Type uPicDesc
    Size As Long
    Type As Long
    hPic As Long
    hPal As Long
End Type

[COLOR=Green]'Windows API Function Declarations[/COLOR]
#If Win64 = 1 And VBA7 = 1 Then
    
   [COLOR=Green] 'Does the clipboard contain a bitmap/metafile?[/COLOR]
    Private Declare PtrSafe Function IsClipboardFormatAvailable Lib "user32" (ByVal wFormat As Integer) As Long
    
    [COLOR=Green]'Open the clipboard to read[/COLOR]
    Private Declare PtrSafe Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
    
    [COLOR=Green]'Get a pointer to the bitmap/metafile[/COLOR]
    Private Declare PtrSafe Function GetClipboardData Lib "user32" (ByVal wFormat As Integer) As Long
    
    [COLOR=Green]'Close the clipboard[/COLOR]
    Private Declare PtrSafe Function CloseClipboard Lib "user32" () As Long
    
   [COLOR=Green] 'Convert the handle into an OLE IPicture interface.[/COLOR]
    Private Declare PtrSafe Function OleCreatePictureIndirect Lib "oleaut32.dll" (PicDesc As uPicDesc, RefIID As GUID, ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long
    
   [COLOR=Green] 'Create our own copy of the metafile, so it doesn't get wiped out by subsequent clipboard updates.[/COLOR]
    Declare PtrSafe Function CopyEnhMetaFile Lib "gdi32" Alias "CopyEnhMetaFileA" (ByVal hemfSrc As Long, ByVal lpszFile As String) As Long
    
    [COLOR=Green]'Create our own copy of the bitmap, so it doesn't get wiped out by subsequent clipboard updates.[/COLOR]
    Declare PtrSafe Function CopyImage Lib "user32" (ByVal handle As Long, ByVal un1 As Long, ByVal n1 As Long, ByVal n2 As Long, ByVal un2 As Long) As Long
    
   [COLOR=Green] 'Uses the Keyboard simulation[/COLOR]
    Private Declare PtrSafe Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

#Else

    [COLOR=Green]'Does the clipboard contain a bitmap/metafile?[/COLOR]
    Private Declare Function IsClipboardFormatAvailable Lib "user32" (ByVal wFormat As Integer) As Long
    
    [COLOR=Green]'Open the clipboard to read[/COLOR]
    Private Declare Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
    
    [COLOR=Green]'Get a pointer to the bitmap/metafile[/COLOR]
    Private Declare Function GetClipboardData Lib "user32" (ByVal wFormat As Integer) As Long
    
    [COLOR=Green]'Close the clipboard[/COLOR]
    Private Declare Function CloseClipboard Lib "user32" () As Long
    
    [COLOR=Green]'Convert the handle into an OLE IPicture interface.[/COLOR]
    Private Declare Function OleCreatePictureIndirect Lib "oleaut32.dll" (PicDesc As uPicDesc, RefIID As GUID, ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long
    
    [COLOR=Green]'Create our own copy of the metafile, so it doesn't get wiped out by subsequent clipboard updates.[/COLOR]
    Declare Function CopyEnhMetaFile Lib "gdi32" Alias "CopyEnhMetaFileA" (ByVal hemfSrc As Long, ByVal lpszFile As String) As Long
    
   [COLOR=Green] 'Create our own copy of the bitmap, so it doesn't get wiped out by subsequent clipboard updates.[/COLOR]
    Declare Function CopyImage Lib "user32" (ByVal handle As Long, ByVal un1 As Long, ByVal n1 As Long, ByVal n2 As Long, ByVal un2 As Long) As Long
    
   [COLOR=Green] 'Uses the Keyboard simulation[/COLOR]
    Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

#End If
  
[COLOR=Green]'The API format types we're interested in[/COLOR]
Const CF_BITMAP = 2
Const CF_PALETTE = 9
Const CF_ENHMETAFILE = 14
Const IMAGE_BITMAP = 0
Const LR_COPYRETURNORG = &H4

Private Const KEYEVENTF_KEYUP = &H2
Private Const VK_SNAPSHOT = &H2C
Private Const VK_MENU = &H12

[COLOR=Green]' Subroutine    : AltPrintScreen
' Purpose       : Capture the Active window, and places on the Clipboard.[/COLOR]

Sub AltPrintScreen()
    keybd_event VK_MENU, 0, 0, 0
    keybd_event VK_SNAPSHOT, 0, 0, 0
    keybd_event VK_SNAPSHOT, 0, KEYEVENTF_KEYUP, 0
    keybd_event VK_MENU, 0, KEYEVENTF_KEYUP, 0
End Sub

[COLOR=Green]' Subroutine    : PastePicture
' Purpose       : Get a Picture object showing whatever's on the clipboard.[/COLOR]

Function PastePicture() As IPicture
    [COLOR=Green]'Some pointers[/COLOR]
    Dim h As Long, hPtr As Long, hPal As Long, lPicType As Long, hCopy As Long

    [COLOR=Green]'Check if the clipboard contains the required format[/COLOR]
    If IsClipboardFormatAvailable(CF_BITMAP) Then
        [COLOR=Green]'Get access to the clipboard[/COLOR]
        h = OpenClipboard(0&)
        If h > 0 Then
            [COLOR=Green]'Get a handle to the image data[/COLOR]
            hPtr = GetClipboardData(CF_BITMAP)

            hCopy = CopyImage(hPtr, IMAGE_BITMAP, 0, 0, LR_COPYRETURNORG)

           [COLOR=Green] 'Release the clipboard to other programs[/COLOR]
            h = CloseClipboard
            [COLOR=Green]'If we got a handle to the image, convert it into a Picture object and return it[/COLOR]
            If hPtr <> 0 Then Set PastePicture = CreatePicture(hCopy, 0, CF_BITMAP)
        End If
    End If
End Function


[COLOR=Green]' Subroutine    : CreatePicture
' Purpose       : Converts a image (and palette) handle into a Picture object.
' NOTE          : Requires a reference to the "OLE Automation" type library[/COLOR]

Private Function CreatePicture(ByVal hPic As Long, ByVal hPal As Long, ByVal lPicType) As IPicture
   [COLOR=Green] ' IPicture requires a reference to "OLE Automation"[/COLOR]
    Dim r As Long, uPicInfo As uPicDesc, IID_IDispatch As GUID, IPic As IPicture
   [COLOR=Green] 'OLE Picture types[/COLOR]
    Const PICTYPE_BITMAP = 1
    Const PICTYPE_ENHMETAFILE = 4
    [COLOR=Green]' Create the Interface GUID (for the IPicture interface)[/COLOR]
    With IID_IDispatch
        .Data1 = &H7BF80980
        .Data2 = &HBF32
        .Data3 = &H101A
        .Data4(0) = &H8B
        .Data4(1) = &HBB
        .Data4(2) = &H0
        .Data4(3) = &HAA
        .Data4(4) = &H0
        .Data4(5) = &H30
        .Data4(6) = &HC
        .Data4(7) = &HAB
    End With
    [COLOR=Green]' Fill uPicInfo with necessary parts.[/COLOR]

    With uPicInfo
        .Size = Len(uPicInfo) ' Length of structure.
        .Type = PICTYPE_BITMAP ' Type of Picture
        .hPic = hPic ' Handle to image.
        .hPal = hPal ' Handle to palette (if bitmap).
    End With

    [COLOR=Green]' Create the Picture object.[/COLOR]
    r = OleCreatePictureIndirect(uPicInfo, IID_IDispatch, True, IPic)

   [COLOR=Green] ' If an error occured, show the description[/COLOR]
    If r <> 0 Then Debug.Print "Create Picture: " & fnOLEError(r)

    [COLOR=Green]' Return the new Picture object.[/COLOR]
    Set CreatePicture = IPic
End Function


[COLOR=Green]' Subroutine    : fnOLEError
' Purpose       : Gets the message text for standard OLE errors[/COLOR]

Private Function fnOLEError(lErrNum As Long) As String
   [COLOR=Green] 'OLECreatePictureIndirect return values[/COLOR]
    Const E_ABORT = &H80004004
    Const E_ACCESSDENIED = &H80070005
    Const E_FAIL = &H80004005
    Const E_HANDLE = &H80070006
    Const E_INVALIDARG = &H80070057
    Const E_NOINTERFACE = &H80004002
    Const E_NOTIMPL = &H80004001
    Const E_OUTOFMEMORY = &H8007000E
    Const E_POINTER = &H80004003
    Const E_UNEXPECTED = &H8000FFFF
    Const S_OK = &H0

    Select Case lErrNum
        Case E_ABORT
            fnOLEError = " Aborted"
        Case E_ACCESSDENIED
            fnOLEError = " Access Denied"
        Case E_FAIL
            fnOLEError = " General Failure"
        Case E_HANDLE
            fnOLEError = " Bad/Missing Handle"
        Case E_INVALIDARG
            fnOLEError = " Invalid Argument"
        Case E_NOINTERFACE
            fnOLEError = " No Interface"
        Case E_NOTIMPL
            fnOLEError = " Not Implemented"
        Case E_OUTOFMEMORY
            fnOLEError = " Out of Memory"
        Case E_POINTER
            fnOLEError = " Invalid Pointer"
        Case E_UNEXPECTED
            fnOLEError = " Unknown Error"
        Case S_OK
            fnOLEError = " Success!"
    End Select
End Function

[COLOR=Green]' Routine   : SaveClip2Bit
' Purpose   : Saves Picture object to desired location.
' Arguments : Path to save the file[/COLOR]

Public Sub SaveClip2Bit(savePath As String)
On Error GoTo errHandler:
    AltPrintScreen
    Pause (3)
    SavePicture PastePicture, savePath
errExit:
        Exit Sub
errHandler:
    Debug.Print "Save Picture: (" & Err.Number & ") - " & Err.Description
    Resume errExit
End Sub

[COLOR=Green]' Routine   : Pause
' Purpose   : Gives a short intreval for proper image capture.
' Arguments : Seconds to wait.[/COLOR]

Public Function Pause(NumberOfSeconds As Variant)
On Error GoTo Err_Pause
    Dim PauseTime As Variant, start As Variant
    PauseTime = NumberOfSeconds
    start = Timer
    Do While Timer < start + PauseTime
        DoEvents
    Loop
Exit_Pause:
    Exit Function
Err_Pause:
    MsgBox Err.Number & " - " & Err.Description, vbCritical, "Pause()"
    Resume Exit_Pause
End Function
I have designed a small sample (attached), for further understanding. Hope this helps.
 

Attachments

  • PrintScreen - Sample.mdb
    304 KB · Views: 1,604
Last edited:

lkmason23

New member
Local time
Today, 06:24
Joined
Jun 7, 2018
Messages
1
Hi! This was really useful thank you. Is there a way to manipulate the Sub AltPrintScreen to capture a webbrowser window within a form?
 

isladogs

MVP / VIP
Local time
Today, 10:24
Joined
Jan 14, 2017
Messages
18,186
Post 2 was moderated. This is to trigger email notifications
 
Status
Not open for further replies.

Users who are viewing this thread

Top Bottom