Short-cut keys

[Hellfire]

Hi All,

Is there any way of stopping the Shift key from functioning, but getting something else in it's place to do the same thing?

I don't want to lock myself out by not being able to get to the db window, but I don't want my users to have access either.
(They know about holding down shift!)

Please help if it is not to complicated. Otherwise....I'm open for suggestions.

Thanks

 

[Fizzio]

Demo on its way (with the other one I created for you!)

 

[ghudson]

'This function and the command button code below will allow you to use a password protected input box to determine if the Shift key can be disabled or not.

*You might have to set your "References" to DAO 3.6. When you are in Module view, go to Tools menu>References>Look for Microsoft DAO 3.6. Then explicitly dimension your code, i.e...
Dim db As DAO.Database, prp As DAO.Property

'Copy this into a new public module...
Option Compare Database
Option Explicit

Public Function SetProperties(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer
On Error GoTo Err_SetProperties
Dim db As Database, prp As Property
Set db = CurrentDb
db.Properties(strPropName) = varPropValue
SetProperties = True
Set db = Nothing
Exit_SetProperties:
Exit Function
Err_SetProperties:
If Err = 3270 Then 'Property not found
Set prp = db.CreateProperty(strPropName, varPropType, varPropValue)
db.Properties.Append prp
Resume Next
Else
SetProperties = False
MsgBox "SetProperties", Err.Number, Err.Description
Resume Exit_SetProperties
End If
End Function

'Assign this to the OnClick event of a command (transparent?) button named "bDisableBypassKey"
'Change the "TypeYourBypassPasswordHere" default password
Private Sub bDisableBypassKey_Click()
On Error GoTo Err_bDisableBypassKey_Click
'This ensures the user is the programmer needing to disable the Bypass Key
Dim strInput As String
Dim strMsg As String
Beep
strMsg = "Do you want to enable the Bypass Key?" & vbCrLf & vbLf & "Please key the programmer's password to enable the Bypass Key."
strInput = InputBox(Prompt:=strMsg, title:="Disable Bypass Key Password")
If strInput = "TypeYourBypassPasswordHere" Then
SetProperties "AllowBypassKey", dbBoolean, True
Beep
MsgBox "The Bypass Key has been enabled." & vbCrLf & vbLf & "The Shift key will allow the users to bypass the startup options the next time the database is opened.", vbInformation, "Set Startup Properties"
Else
Beep
SetProperties "AllowBypassKey", dbBoolean, False
MsgBox "Incorrect ''AllowBypassKey'' Password!" & vbCrLf & vbLf & "The Bypass Key was disabled." & vbCrLf & vbLf & "The Shift key will NOT allow the users to bypass the startup options the next time the database is opened.", vbCritical, "Invalid Password"
Exit Sub
End If
Exit_bDisableBypassKey_Click:
Exit Sub
Err_bDisableBypassKey_Click:
MsgBox "bDisableBypassKey_Click", Err.Number, Err.Description
Resume Exit_bDisableBypassKey_Click
End Sub

HTH

 

[Hellfire]

Thanks All,

Got it sorted. That demo you sent me worked perfectly Fizzio, Thank you.