form with dynamically shifted controls (1 Viewer)

Private Sub cmboFirm_AfterUpdate()
  If Not IsNull(Me.cmboFirm) Then LoadPages (Me.cmboFirm)
    
End Sub

Private Sub Form_Load()
  Dim i As Integer
  Me.TxtFocus.SetFocus
  For i = 0 To Me.tabCtlIndex.Pages.Count - 1
    Me.tabCtlIndex.Pages(i).Visible = False
  Next i
  Me.TxtFocus.SetFocus
  Me.subFrmPartner.Visible = False
End Sub

Public Sub LoadPages(FirmName As String)
  Dim RS As DAO.Recordset
  Dim tc As TabControl
  Dim PartnerCount As Integer
  Set tc = Me.tabCtlIndex
  
  Set RS = CurrentDb.OpenRecordset("Select * from TblPartners where FirmName = '" & FirmName & "'")
  If Not RS.EOF And Not RS.BOF Then
    RS.MoveLast
    RS.MoveFirst
    PartnerCount = RS.RecordCount
   ' AddNames
  End If
  Me.Painting = False
  Me.TxtFocus.SetFocus
  AddNames RS
  HidePages 0
  ShowPages PartnerCount
  Me.subFrmPartner.Visible = True
  Me.Painting = True
End Sub

Public Sub HidePages(PartnerCount As Integer)
  Dim i As Integer
  For i = PartnerCount To Me.tabCtlIndex.Pages.Count - 1
    Me.tabCtlIndex.Pages(i).Visible = False
  Next i
End Sub
Public Sub ShowPages(PartnerCount As Integer)
  Dim i As Integer
  For i = 0 To PartnerCount - 1
    Me.tabCtlIndex.Pages(i).Visible = True
  Next i
End Sub
Public Sub AddNames(RS As DAO.Recordset)
  Dim PartnerName As String
  Dim i As Integer
  Do While Not RS.EOF
     PartnerName = RS!FullName
     With Me.tabCtlIndex.Pages(i)
       .Caption = PartnerName
       .Tag = RS!PartnerID
     End With
     i = i + 1
     RS.MoveNext
  Loop
End Sub

Private Sub tabCtlIndex_Change()
  LinkSubForm
End Sub
Private Sub LinkSubForm()
  Dim PartnerID As Long
  Dim strID As String
  strID = Me.tabCtlIndex.Pages(Me.tabCtlIndex.Value).Tag
  If strID = "" Then strID = "0"
  PartnerID = CLng(strID)
  Me.subFrmPartner.Form.Recordset.FindFirst "PartnerID = " & CLng(PartnerID)
End Sub