Chaining Forms lockup

[ClaraBarton]

I've added Pat Hartman's code for chaining forms. Everything was going merrily along until suddenly things were locking up and I had to use task manager to get out of Access. After much time I think I traced the problem to this code:

Private Sub Form_Unload(Cancel As Integer)
    Call sUnload(Me)
End Sub

I can't really put my finger on it but I notice in the locals window this:

I went back to the chaining forms example and I notice that her's shows the same thing. It doesn't seem to be an error, only shows in the locals window. Is this typical? If I comment out the unload sub I don't get locked out but of course... it doesn't work.

 

[jdraw]

Can you post your database or enough of it (event code) to show the issue and any messages/errors?

 

[ClaraBarton]

You can chain through the forms fine but if you stop and open any one in design view it will lock up.

 

[MajP]

I took a look at it and cannot figure it out. I tried to debug and clean up some of the code, and have no idea what is going on.
For others the bottom line is if you go into design mode of a form the application locks ups. The OP is correct in that if you remove the "chaining" code this does not happen.

here is the code

Option Compare Database
Option Explicit
'Pat Hartman; chaining forms
Global gFrmName As String

Public Sub sOpenForm(frm As Form, frmName As String, intID As Integer)
    Dim strLongFormName As String
    Dim strWhere As String
           
    frm.Visible = False 'calling form
    strLongFormName = "Forms!" & frm.Name
          If intID > 0 Then
            strWhere = "[BookID] = " & intID

            DoCmd.OpenForm frmName, _
                WhereCondition:=strWhere, _
                OpenArgs:=strLongFormName
   
        Else
            DoCmd.OpenForm frmName, _
               OpenArgs:=strLongFormName
        End If
   
End Sub

Public Sub sUnload(frm As Form)
    Dim strShortFormName As String

    gFrmName = frm.Name
    If IsNull(frm.OpenArgs) Then
        DoCmd.OpenForm "frmMenu", acNormal, , , acFormEdit, acDialog
       
    Else
        strShortFormName = Mid(frm.OpenArgs, InStrRev(frm.OpenArgs, "!") + 1)
        DoCmd.OpenForm strShortFormName
    End If
End Sub

Public Sub sActivate(frm As Form)
    frm!txtOpenedBy = gFrmName
    gFrmName = frm.Name
End Sub

When a form loads the sActivate is called when it unloads the sUnload is called.

When you go into design view I assume that will trigger the form's unload event and thus the sUnload method.

 

[KitaYama]

For others the bottom line is if you go into design mode of a form the application locks ups.

Changing the Modal property of the frmMenu to NO, solves the problem.

 

[ClaraBarton]

OOOH! Thank you so much! Fixed and moving on!

 

[Pat Hartman]

I would be careful about how many forms get left open. And you don't want to have any given form opened multiple times