Hide All Access Objects (1 Viewer)

speakers_86

Registered User.
Local time
Today, 07:28
Joined
May 17, 2007
Messages
1,919
Code:
Public Sub HideObjects(Optional booHide As Boolean)
    'Created by Speakers_86
    'You are free to use, modify, and distribute
    'this as long as you leave this comment
    '
    'Purpose:   loops through all of you access objects, and
    '           hides them, the same as using the Access Gui to
    '           hide an object
    'Argument:  booHide
    '           an optional argument.  True hides objects,
    '           false unhides objects
    

    Dim db     As Database
    Dim tbl    As TableDef
    Dim qry    As QueryDef
    Dim str    As String
    Dim i      As Integer

    On Error Resume Next
    
    Set db = CurrentDb()


    For Each tbl In db.TableDefs
            Call SetHiddenAttribute(acTable, tbl.Name, booHide)
    Next tbl


    For Each qry In db.QueryDefs
        Call SetHiddenAttribute(acQuery, qry.Name, booHide)
    Next qry


    For i = 0 To db.Containers("Forms").Documents.Count - 1
        str = db.Containers("Forms").Documents(i).Name
        Call SetHiddenAttribute(acForm, str, booHide)
    Next



    For i = 0 To db.Containers("Reports").Documents.Count - 1
        str = db.Containers("Reports").Documents(i).Name
        Call SetHiddenAttribute(acReport, str, booHide)
    Next i


    For i = 0 To db.Containers("Modules").Documents.Count - 1
        str = db.Containers("Modules").Documents(i).Name
        Call SetHiddenAttribute(acModule, str, booHide)
    Next i



    For i = 0 To db.Containers("Scripts").Documents.Count - 1
        str = db.Containers("Scripts").Documents(i).Name
        Call SetHiddenAttribute(acMacro, str, booHide)
    Next i

    Set db = Nothing
End Sub
 

Users who are viewing this thread

Top Bottom