Log which version of access is on pc.

[tucker61]

When a user logs into my db I currently log login time , userid and pc number.. is it also possible via code to pull back which version of access they are using ? My db is currently in access 2000, but I am thinking of moving this to a later version (if all users have later version installed)

Sent from my SM-T715 using Tapatalk

 

[isladogs]

Here are 3 functions you can use depending on the level of detail you want:

Function GetAccessVersion() As String
'Gets Access version e.g. 14 for Access 2010
GetAccessVersion = Nz(CInt(SysCmd(acSysCmdAccessVer)), "None")
'Debug.Print GetAccessVersion
End Function

Function GetAccessBuildVersion() As String
'Gets full Access version number including program updates / service packs
'e.g. 14.6024 for Access 2010 SP1
GetAccessBuildVersion = Nz(SysCmd(acSysCmdAccessVer) & "." & SysCmd(715), "None")
'Debug.Print GetAccessBuildVersion
End Function

Function GetAccessEXEVersion() As String

'Valid for use with Access 2000 or later.
'Original version may be from Tom van Stiphout, not sure?

'SysCmd(715) -> 6606
'Application.Version OR SysCmd(acSysCmdAccessVer) -> 12.0
    On Error Resume Next
    Dim sAccessVerNo As String
    
    sAccessVerNo = SysCmd(acSysCmdAccessVer) & "." & SysCmd(715)
    
    Select Case sAccessVerNo
        'Access 2000
        Case "9.0.0.0000" To "9.0.0.2999": GetAccessEXEVersion = "Access 2000 (" & sAccessVerNo & ")"
        Case "9.0.0.3000" To "9.0.0.3999": GetAccessEXEVersion = "Access 2000 SP1 (" & sAccessVerNo & ")"
        Case "9.0.0.4000" To "9.0.0.4999": GetAccessEXEVersion = "Access 2000 SP2 (" & sAccessVerNo & ")"
        Case "9.0.0.6000" To "9.0.0.6999": GetAccessEXEVersion = "Access 2000 SP3 (" & sAccessVerNo & ")"
        
        'Access 2002
        Case "10.0.2000.0" To "10.0.2999.9": GetAccessEXEVersion = "Access 2002 (" & sAccessVerNo & ")"
        Case "10.0.3000.0" To "10.0.3999.9": GetAccessEXEVersion = "Access 2002 SP1 (" & sAccessVerNo & ")"
        Case "10.0.4000.0" To "10.0.4999.9": GetAccessEXEVersion = "Access 2002 SP2 (" & sAccessVerNo & ")"
        
        'Access 2003
        Case "11.0.0000.0" To "11.0.5999.9999": GetAccessEXEVersion = "Access 2003 (" & sAccessVerNo & ")"
        Case "11.0.6000.0" To "11.0.6999.9999": GetAccessEXEVersion = "Access 2003 SP1 (" & sAccessVerNo & ")"
        Case "11.0.7000.0" To "11.0.7999.9999": GetAccessEXEVersion = "Access 2003 SP2 (" & sAccessVerNo & ")"
        Case "11.0.8000.0" To "11.0.8999.9999": GetAccessEXEVersion = "Access 2003 SP3 (" & sAccessVerNo & ")"
        
        'Access 2007
        Case "12.0.0000.0" To "12.0.5999.9999": GetAccessEXEVersion = "Access 2007 (" & sAccessVerNo & ")"
        Case "12.0.6211.0" To "12.0.6422.9999": GetAccessEXEVersion = "Access 2007 SP1 (" & sAccessVerNo & ")"
        Case "12.0.6423.0" To "12.0.5999.9999": GetAccessEXEVersion = "Access 2007 SP2 (" & sAccessVerNo & ")"
        
        'Access 2010
        Case "14.0.0000.0000" To "14.0.6022.1000": GetAccessEXEVersion = "Access 2010 (" & sAccessVerNo & ")"
        Case "14.0.6023.1000" To "14.0.7014.9999": GetAccessEXEVersion = "Access 2010 SP1 (" & sAccessVerNo & ")"
        Case "14.0.7015.1000" To "14.0.9999.9999": GetAccessEXEVersion = "Access 2010 SP2 (" & sAccessVerNo & ")"
        
        'Access 2013
        Case "15.0.0000.0000" To "15.0.4569.1505": GetAccessEXEVersion = "Access 2013 (" & sAccessVerNo & ")"
        Case "15.0.4569.1506" To "15.0.9999.9999": GetAccessEXEVersion = "Access 2013 SP1 (" & sAccessVerNo & ")"
        
        'Access 2016 - to be confirmed
        Case "16.0.0000.0000" To "16.0.4569.1505": GetAccessEXEVersion = "Access 2016 (" & sAccessVerNo & ")"
        Case "16.0.4569.1506" To "16.0.9999.9999": GetAccessEXEVersion = "Access 2016 SP1 (" & sAccessVerNo & ")"
        
        Case Else: GetAccessEXEVersion = "Access - Unknown Version"
        
    End Select
    
    If SysCmd(acSysCmdRuntime) Then GetAccessEXEVersion = GetAccessEXEVersion & " Run-time"
    
   ' Debug.Print GetAccessEXEVersion
End Function