Login to different things

[bdb25]

Hey i'm using the login form from databasedev, and in the tblusers theres a place for either Admin or User, i was wondering what script would have to be included in the login to get Admin's directed to the SwitchboardAdmin and the Users to be directed to SwitchboardUsers.

I've attached the file i'm using, if anyone can help it would be greatly appreciated as i dont know what i'm doing when it comes to scripting

i figre it would be something along the lines of if strlevel = Admin then go to such n such if strLevel = User then go to such n such.

this said, i have no idea in how to put that into a script that works

thanks

 

[rainman89]

use a dlookup to get the user level (strlevel)
then

Dim Struserlevel as string
struserlevel = DLookup("strlevel", "tblEmployees", "[lngEmpID]=" & Me.cboEmployee.Value)
        If (strUserlevel = "Admin") Then
        DoCmd.Close acForm, "frmLogon", acSaveNo
        DoCmd.OpenForm "SwitchboardAdmin"
        Else
        DoCmd.Close acForm, "frmLogon", acSaveNo
        DoCmd.OpenForm "SwitchboardUsers"
        end if

Something along those lines

 

[bdb25]

i've had a mess about and tried to add it into the code so now it reads

'Close logon form and open splash screen
        
Dim Struserlevel As String
Struserlevel = DLookup("strlevel", "tblEmployees", "[lngEmpID]=" & Me.cboEmployee.Value)
        If (Struserlevel = "Admin") Then
        DoCmd.Close acForm, "frmLogon", acSaveNo
        DoCmd.OpenForm "SwitchboardAdmin"
        Else
        DoCmd.Close acForm, "frmLogon", acSaveNo
        DoCmd.OpenForm "SwitchboardUsers"
        Else
        MsgBox "Password Invalid.  Please Try Again", vbOKOnly, "Invalid Entry!"
        Me.txtPassword.SetFocus
    End If

however when i try and run this code it says Compile Error Else without If

sorry that i need it step by step

i've attached the file again with the script in that i've added

thanks again

 

[boblarson]

You currently have two Else statements and for an If...Then...Else you can only have one unless you use ElseIf statements after the inital Else.

 

[bdb25]

So therefore my code should look something along the lines of.....

Private Sub cmdLogin_Click()

    If IsNull(Me.cboEmployee) Or Me.cboEmployee = "" Then
            MsgBox "You must enter a User Name.", vbOKOnly, "Required Data"
            Me.cboEmployee.SetFocus
        Exit Sub
    End If

    If IsNull(Me.txtPassword) Or Me.txtPassword = "" Then
            MsgBox "You must enter a Password.", vbOKOnly, "Required Data"
            Me.txtPassword.SetFocus
        Exit Sub
    End If

    If Me.txtPassword.Value = DLookup("strEmpPassword", "tblEmployees", "[lngEmpID]=" & Me.cboEmployee.Value) Then

        lngMyEmpID = Me.cboEmployee.Value
       
        Dim Struserlevel As String
        Struserlevel = DLookup("strlevel", "tblEmployees", "[lngEmpID]=" & Me.cboEmployee.Value)
        If (Struserlevel = "Admin") Then
        DoCmd.Close acForm, "frmLogon", acSaveNo
        DoCmd.OpenForm "SwitchboardAdmin"
        
        Else
        DoCmd.Close acForm, "frmLogon", acSaveNo
        DoCmd.OpenForm "SwitchboardUsers"

        ElseIf
        MsgBox "Password Invalid.  Please Try Again", vbOKOnly, "Invalid Entry!"
        Me.txtPassword.SetFocus
    End If
    
End Sub

only thing is when i type in ElseIf it turns red and a prompt is displayed saying Compile Error: Expected Expression

am i missing something really simple? (probably knowing me)

 

[boblarson]

Actually, I led you slightly astray. Sorry, it's Monday and my brain isn't working too well.

You should try changing it to this:

Private Sub cmdLogin_Click()

    If IsNull(Me.cboEmployee) Or Me.cboEmployee = "" Then
            MsgBox "You must enter a User Name.", vbOKOnly, "Required Data"
            Me.cboEmployee.SetFocus
        Exit Sub
    End If

    If IsNull(Me.txtPassword) Or Me.txtPassword = "" Then
            MsgBox "You must enter a Password.", vbOKOnly, "Required Data"
            Me.txtPassword.SetFocus
        Exit Sub
    End If

    If Me.txtPassword.Value = DLookup("strEmpPassword", "tblEmployees", "[lngEmpID]=" & Me.cboEmployee.Value) Then

        lngMyEmpID = Me.cboEmployee.Value
       
    End If

        Dim Struserlevel As String
        Struserlevel = DLookup("strlevel", "tblEmployees", "[lngEmpID]=" & Me.cboEmployee.Value)
	Select Case Struserlevel
		Case "Admin"
		        DoCmd.Close acForm, "frmLogon", acSaveNo
		        DoCmd.OpenForm "SwitchboardAdmin"
        
        	Case "User"
		        DoCmd.Close acForm, "frmLogon", acSaveNo
		        DoCmd.OpenForm "SwitchboardUsers"

		Case Else

        		MsgBox "Password Invalid.  Please Try Again", vbOKOnly, "Invalid Entry!"
        		Me.txtPassword.SetFocus
    	End Select
    
End Sub

 

[bdb25]

thanks so much for all your help, works like a charm now woo

edit: ok i spoke too soon, it works, however, even if the password is wrong, it still logs you in *-) is there anyway of getting around this, i've had a play at moving different parts around, and i can get it to say "invalid password" however it still goes on to load the switchboard.

 

[rainman89]

move your case statement inside the if statement that u have that checks the password

Private Sub cmdLogin_Click()
    If IsNull(Me.cboEmployee) Or Me.cboEmployee = "" Then
            MsgBox "You must enter a User Name.", vbOKOnly, "Required Data"
            Me.cboEmployee.SetFocus
        Exit Sub
    End If
    If IsNull(Me.txtPassword) Or Me.txtPassword = "" Then
            MsgBox "You must enter a Password.", vbOKOnly, "Required Data"
            Me.txtPassword.SetFocus
        Exit Sub
    End If
    If Me.txtPassword.Value = DLookup("strEmpPassword", "tblEmployees", "[lngEmpID]=" & Me.cboEmployee.Value) Then
        lngMyEmpID = Me.cboEmployee.Value
        Dim Struserlevel As String
        Struserlevel = DLookup("strlevel", "tblEmployees", "[lngEmpID]=" & Me.cboEmployee.Value)
	Select Case Struserlevel
		Case "Admin"
		        DoCmd.Close acForm, "frmLogon", acSaveNo
		        DoCmd.OpenForm "SwitchboardAdmin"
        
        	Case "User"
		        DoCmd.Close acForm, "frmLogon", acSaveNo
		        DoCmd.OpenForm "SwitchboardUsers"

		Case Else

        		MsgBox "Password Invalid.  Please Try Again", vbOKOnly, "Invalid Entry!"
        		Me.txtPassword.SetFocus
    	End Select
Else
Msgbox "Error: Username and password do not match"
    end if
End Sub

 

[bdb25]

thanks alot all sorted

 

[rainman89]

Glad to hear it!