Looping through files in a directory

[rberkers]

Hi,

If have written a small VBA program that shows all the files in a directory and it works as a charm:

Public Sub LoopFiles()

    Dim strPath As String

    Dim objFso As FileSystemObject
    Dim objFolder As Folder
    Dim objFile As File
    
    strPath = "C:\Windows"

    Set objFso = New FileSystemObject
    Set objFolder = objFso.GetFolder(strPath)
    
    For Each objFile In objFolder.Files
        Debug.Print objFile.Name
    Next
        
End Sub

What I would like that it only shows the files of a certain filemask. Is it possible to use the FileSystemObject to get only the files of a certain filemask and loop through them?

Thanks in advance.

Regards,
Rob.

 

[DJkarl]

Maybe something like

        If objFile.name Like "*.dll" Then
            Debug.Print objFile.name
        End If

of course you could make the "*.dll" a parameter to the function rather than hard-coding it but you get the idea.

 

[datAdrenaline]

Any reason why you want to use the FileSystemObject library?

Public Sub LoopFiles()
    Dim strPath As String
    Dim strFilename As String
    
    strPath = "C:\Windows\*.dll"
    
    strFilename = Dir(strPath)
    Do Until strFilename = ""
        Debug.Print strFilename
        strFilename = Dir
    Loop
        
End Sub

 

[rberkers]

of course you could make the "*.dll" a parameter to the function rather than hard-coding it but you get the idea.

Thanks. That looks rather useful.

Rob.

 

[rberkers]

Any reason why you want to use the FileSystemObject library?

I was told that in case of a directory with a huge amount of file-entries the FileSystemObject would be faster as use "DIR".

Regards,
Rob.