My access crashes when opening form with Modern Chart and Subform control (1 Viewer)

[Babycat]

Hi everyone
Please help.
On my design:

1. Left-side: a continuous form (SubForm) that shows list of product
2 Right-side (on MainFrm) show product detail of selected product in left-side.
3. Modern chart to show price/qty over time of current product
4. SubForm, MainFrm bound to tblProduct
5. The MainFrm is opened from FormA by a button (attached picture)

Intention: When user clicks on a product row (on continuous form - SubForm) the MainFrm will show that product's detail.

Crash issue:
Happen when combobox = 2 or 3.
Not happend if combobox = 1 or we remove the modern Chart

Code on FormA to open selected productID (via form open argument)

Private Sub Btn_ViewProduct_Click()

    DoCmd.OpenForm "MainFrm", , , , , , Combo0 & ""
 
End Sub

Code on the SubForm

Private Sub Form_Current()
Dim rs As DAO.Recordset

    Set rs = Me.Form.Parent.Form.Recordset
    With rs
            .FindFirst "[ProductID] = " & Txt_ID
            If .NoMatch Then
                MsgBox "Unknow Error - No ProductID " & ProductID & " !"
            End If
    End With
    Set rs = Nothing
 
End Sub

Private Sub Form_Load()
Dim pID As Long
Dim argStr As String
Dim rs As DAO.Recordset

    If Me.Parent.Form.OpenArgs & "" = "" Then '
        'Dont need to go any record
    Else
        pID = Val(Me.Parent.Form.OpenArgs & "")
        Set rs = Me.Recordset
        With rs
            .FindFirst "[ProductID] = " & pID
            If .NoMatch Then
                MsgBox "Unknow Error - No ProductID " & ProductID & " !"
            End If
        End With
        Set rs = Nothing
    End If
End Sub

My suspect:
- On the FormA, user selected ProductID 2 to view
- MainFrm is loading its control and chart belong to productID 1 (by default sorting)
- at this the, subform forces MainFrm to show productID 2
- The chart of productID 1 is not finish loading yet, --> Access crashes

 

[RonPaii]

FormA attemps to load FormX which does not exist. Opening MainFrm

'    DoCmd.OpenForm "FormX", , , , , , Combo0 & ""
    DoCmd.OpenForm "MainFrm", , , , , , Combo0 & ""

SubForm Form_Current attempts to search the "MainFrm" recordset after searching in the sub. Why not link in main and search in main.

Your search can be much easer using bookmark.

        With Me.RecordsetClone
            .FindFirst "[ProductID] = " & pID
            If .NoMatch Then
                MsgBox "Unknow Error - No ProductID " & ProductID & " !"
            Else
                Me.Bookmark = .Bookmark
            End If
        End With

Try adding error trapping and logging, at least debug.print to see the errors as they are raised.

 

[RonPaii]

Move the load event to the main form.

Private Sub Form_Load()
    On Error GoTo errForm_Load
    If Me.OpenArgs & "" = "" Then
        'Dont need to go any record
    Else
        With Me.RecordsetClone
            .FindFirst "[ProductID] = " & CLng(Me.OpenArgs)
            If .NoMatch Then
                MsgBox "Unknow Error - No ProductID " & CLng(Me.OpenArgs) & " !"
            Else
                Me.Bookmark = .Bookmark
            End If
        End With
    End If
doneForm_Load:
    Exit Sub
errForm_Load:
    Debug.Print "MainFrm.Form_Load error: " & Err.Number, Err.Description
    Resume doneForm_Load
End Sub

Skip the lookup of main form on 1st call of on_current in the sub-form.

Private Sub Form_Current()
    On Error GoTo errForm_Current
    Static NextCall As Boolean ' Sub-Form opens before main
    If Not NextCall Then
        NextCall = True
    Else
        With Me.Form.Parent.Form.RecordsetClone
            .FindFirst "[ProductID] = " & Txt_ID
            If .NoMatch Then
                MsgBox "Unknow Error - No ProductID " & ProductID & " !"
            Else
                Me.Form.Parent.Form.Bookmark = .Bookmark
            End If
        End With
    End If
doneForm_Current:
    Exit Sub
errForm_Current:
    Debug.Print "SubForm.Form_Current error: " & Err.Number, Err.Description
    Resume doneForm_Current
End Sub

 

[Babycat]

FormA attemps to load FormX which does not exist. Opening MainFrm

It was just my typo.

I tried with your code

Me.Bookmark = .Bookmark

But it is same crash...

 

[Babycat]

Move the load event to the main form.

Skip the lookup of main form on 1st call of on_current in the sub-form.

Look good idea. let me try

 

[Babycat]

It's working bro,
Two consecutive searches in sub-form load and current event might causes main form overloaded especially it contains modern chart. So we skip the first call then it works

btw: These two below code snipes work but any performance difference?

        With Me.RecordsetClone
            .FindFirst "[ProductID] = " & CLng(Me.OpenArgs)
            If .NoMatch Then
            Else
                Me.Bookmark = .Bookmark
            End If
        End With

        With Me.Recordset
            .FindFirst "[ProductID] = " & CLng(Me.OpenArgs)
        End With

I noticed they jump to exactly searched ProductID

 

[Gasman]

Have you tried your code with a non existent ProductID?

 

[Babycat]

Have you tried your code with a non existent ProductID?

Yes, it just simply opens the first record of tblProduct, this is expected.

 

[Babycat]

Move the load event to the main form.

Hi RonPaii

I found an issue here. If we skip the first time of subform's current event, then the mainform and subform will not be synched same record ID

 

[arnelgp]

here you may try to test.
It is not the modern chart's fault.
it is because it is creating an Endless loop.

 

[Babycat]

here you may try to test.
It is not the modern chart's fault.
it is because it is creating an Endless loop.

Thank your your help. It works and I am studying your code...

btw: what was the endless loop in vba code?
I have debugged my original db in post #1 and found that:
- If combobox productID = 1, sub-form's current event fires 1 time (probably mainfrm is alo loading data of ProductID = 1
- If combobox productID <> 1, sub-form's current event fires 2 time consecutive... This time form crashes

My concern part is: Why same code, same design but form does not crash if I remove modern chart object?