compile error

[Weresmytriple]

hi all when i am using this code

Option Compare Database
Public Function RunAtStart()
'    KillIt
    DetermineByPass

End Function

Public Function KillIt() As Integer

    If SysCmd(SYSCMD_RUNTIME) = 0 Then
        MsgBox ("This Application cannot be opened directly with Microsoft Access," & vbCrLf & _
        "and can ONLY be opened with the desktop shortcut." & vbCrLf & vbCrLf & _
        "Please double click the shortcut on your desktop to open This Application." & vbCrLf & vbCrLf & _
        "This application will now close."), vbOKOnly, "My Application Name"
        Application.Quit
    End If
End Function

Public Function DetermineByPass()
    If Len(Dir(CurrentProject.Path & "\LetMeIn.txt")) = 0 Then
        SetStartupProperties (False)
    Else
        SetStartupProperties (True)
    End If
End Function

Public Sub SetStartupProperties(bolParameter As Boolean)

    ChangeProperty "StartupShowDBWindow", dbBoolean, bolParameter
    ChangeProperty "AllowBreakIntoCode", dbBoolean, bolParameter
    ChangeProperty "AllowSpecialKeys", dbBoolean, bolParameter
    ChangeProperty "AllowBypassKey", dbBoolean, bolParameter
    ChangeProperty "StartupShowStatusBar", dbBoolean, bolParameter
    ChangeProperty "AllowBuiltinToolbars", dbBoolean, bolParameter
    ChangeProperty "AllowFullMenus", dbBoolean, bolParameter
    ChangeProperty "AllowShortcutMenus", dbBoolean, bolParameter

End Sub

Public Function ChangeProperty(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer
    Dim dbs As Database, prp As Property
    Const conPropNotFoundError = 3270

    Set dbs = CurrentDb
    On Error GoTo Change_Err
    dbs.Properties(strPropName) = varPropValue
    ChangeProperty = True

Change_Bye:
    Exit Function

Change_Err:
    If Err = conPropNotFoundError Then  ' Property not found.
        Set prp = dbs.CreateProperty(strPropName, _
        varPropType, varPropValue)
        dbs.Properties.Append prp
        Resume Next
    Else
        ' Unknown error.
        ChangeProperty = False
        Resume Change_Bye
    End If
End Function

i am getting the compile error of you may have entered a comma without a preceding value or identifier

can any one spot this error? and help me fix it

thanks

michael

 

[CJ_London]

looks like your KillIt msgbox is wrong - you don't need the brackets anyway, but if you did the one on the last line should be at the end

 

[Weresmytriple]

i dont think its that as i have deleted the entire function and i am still getting the same compile error

 

[pr2-eugin]

CJ is correct, try this !

Public Function KillIt() As Integer
    If SysCmd(SYSCMD_RUNTIME) = 0 Then
        MsgBox "This Application cannot be opened directly with Microsoft Access," & vbCrLf & _
               "and can ONLY be opened with the desktop shortcut." & vbCrLf & vbCrLf & _
               "Please double click the shortcut on your desktop to open This Application." & vbCrLf & vbCrLf & _
               "This application will now close.", vbOKOnly, "My Application Name"
        Application.Quit
    End If
End Function

 

[JHB]

The code does not give any error by me, so in which line do you get the error message?

 

[JHB]

...you don't need the brackets anyway, but if you did the one on the last line should be at the end

Correct he doesn't need the brackets, but no it doesn't need to be at the end only if he want to assign the return value to a variable and in this case he doesn't want it so he's code for the MsgBox is correct..

 

[CJ_London]

I notice there is a parallel thread to this

http://www.access-programmers.co.uk/forums/showthread.php?p=1326646#post1326646

- did you just copy and paste the code or type it from scratch? If the latter, are we looking at your actual code that is producing the error or what you copied - which may not have the error