Filter Records: Adding unbound Date listbox to Filter String (1 Viewer)

[mactheknife]

I'm trying to hash two scripts I've found into 1 functioning filter, however I'm still relatively new to vba and can't figure out how to get this working.

I'm trying to use Allen Browne's Search Criteria:

with another snippete of code I found here:

'Purpose:   This module illustrates how to create a search form, _
            where the user can enter as many or few criteria as they wish, _
            and results are shown one per line.
'Note:      Only records matching ALL of the criteria are returned.
'Author:    Allen Browne (allen@allenbrowne.com), June 2006.
Option Compare Database
Option Explicit
 
Private Sub cmdFilter_Click()
    'Purpose:   Build up the criteria string form the non-blank search boxes, and apply to the form's Filter.
    'Notes:     1. We tack " AND " on the end of each condition so you can easily add more search boxes; _
                    we remove the trailing " AND " at the end.
    '           2. The date range works like this: _
                        Both dates      = only dates between (both inclusive. _
                        Start date only = all dates from this one onwards; _
                        End date only   = all dates up to (and including this one).
    Dim strWhere As String                  'The criteria string.
    Dim lngLen As Long                      'Length of the criteria string to append to.
    Const conJetDate = "\#mm\/dd\/yyyy\#"   'The format expected for dates in a JET query string.
 
    '***********************************************************************
    'Look at each search box, and build up the criteria string from the non-blank ones.
    '***********************************************************************
    'Text field example. Use quotes around the value in the string.
    If Not IsNull(Me.txtFilterCity) Then
        strWhere = strWhere & "([City] = """ & Me.txtFilterCity & """) AND "
    End If
 
    'Another text field example. Use Like to find anywhere in the field.
    If Not IsNull(Me.txtFilterMainName) Then
        strWhere = strWhere & "([MainName] Like ""*" & Me.txtFilterMainName & "*"") AND "
    End If
 
    'Number field example. Do not add the extra quotes.
    If Not IsNull(Me.cboFilterLevel) Then
        strWhere = strWhere & "([LevelID] = " & Me.cboFilterLevel & ") AND "
    End If
 
    'Yes/No field and combo example. If combo is blank or contains "ALL", we do nothing.
    If Me.cboFilterIsCorporate = -1 Then
        strWhere = strWhere & "([IsCorporate] = True) AND "
    ElseIf Me.cboFilterIsCorporate = 0 Then
        strWhere = strWhere & "([IsCorporate] = False) AND "
    End If
 
    'Date field example. Use the format string to add the # delimiters and get the right international format.
    If Not IsNull(Me.txtStartDate) Then
        strWhere = strWhere & "([EnteredOn] >= " & Format(Me.txtStartDate, conJetDate) & ") AND "
    End If
 
    'Another date field example. Use "less than the next day" since this field has times as well as dates.
    If Not IsNull(Me.txtEndDate) Then   'Less than the next day.
        strWhere = strWhere & "([EnteredOn] < " & Format(Me.txtEndDate + 1, conJetDate) & ") AND "
    End If
 
    '***********************************************************************
    'Chop off the trailing " AND ", and use the string as the form's Filter.
    '***********************************************************************
    'See if the string has more than 5 characters (a trailng " AND ") to remove.
    lngLen = Len(strWhere) - 5
    If lngLen <= 0 Then     'Nah: there was nothing in the string.
        MsgBox "No criteria", vbInformation, "Nothing to do."
    Else                    'Yep: there is something there, so remove the " AND " at the end.
        strWhere = Left$(strWhere, lngLen)
        'For debugging, remove the leading quote on the next line. Prints to Immediate Window (Ctrl+G).
        'Debug.Print strWhere
 
        'Finally, apply the string as the form's Filter.
        Me.Filter = strWhere
        Me.FilterOn = True
    End If
End Sub
 
Private Sub cmdReset_Click()
    'Purpose: Clear all the search boxes in the Form Header, and show all records again.
    Dim ctl As Control
 
    'Clear all the controls in the Form Header section.
    For Each ctl In Me.Section(acHeader).Controls
        Select Case ctl.ControlType
        Case acTextBox, acComboBox
            ctl.Value = Null
        Case acCheckBox
            ctl.Value = False
        End Select
    Next
 
    'Remove the form's filter.
    Me.FilterOn = False
End Sub
 
Private Sub Form_BeforeInsert(Cancel As Integer)
    'To avoid problems if the filter returns no records, we did not set its AllowAdditions to No.
    'We prevent new records by cancelling the form's BeforeInsert event instead.
    'The problems are explained at
    Cancel = True
    MsgBox "You cannot add new clients to the search form.", vbInformation, "Permission denied."
End Sub
 
Private Sub Form_Open(Cancel As Integer)
    'Remove the single quote from these lines if you want to initially show no records.
    'Me.Filter = "(False)"
    'Me.FilterOn = True
End Sub

Public Sub myComboBox_Change()
    Dim startDate As Date
    Dim endDate As Date
    Dim period As String
 
    period = Me.myComboBox
            startDate = DateSerial(Year(date), Month(date), Day(date))
    Select Case period
        Case "Today"
            endDate = DateAdd("d", 1, startDate)
        Case "Yesterday"
            endDate = startDate
            startDate = DateAdd("d", -1, startDate)
        Case "Last 4 days"
             endDate = startDate
            startDate = DateAdd("d", -4, endDate)
        Case "Last 9 days"
            endDate = startDate
            startDate = DateAdd("d", -9, endDate)
            End Select
    Me.Filter = "WHERE Transaction_Date BETWEEN #" _
        & Format(startDate, "mm/dd/yyyy") & "# AND #" _
        & Format(endDate, "mm/dd/yyyy") & "#"
    Me.FilterOn = True
End Sub

It's the date part I'm having trouble with, the rest of the search criteria work fine without the date, but I can't get it working when I try to modify and merge the date sections of each code.

Also I'm using a listbox for the "Yesterday";"Last 4 days";"Last 9 days" and not a combo box.

Any help would be much appreciated.

 

[jdraw]

And which code is yours?
Where is your listbox -- or did you name it MyCombobox?
You probably need a
Private Sub MyCombobox_Change()

Do you get an error message?
Post all of your code

 

[mactheknife]

Sorry for wasting your time, but I managed to get it working, there was a problem with the date format.

Perhaps you can help me with another problem though. I'm trying to add another field into the filter - Position. However the position field is in a seperate table to the records being filtered.

It is however linked via the relationships.

I've attached a few images to explain the filter form & the table relationships.

What code do I use to filter the report records based on the user position groups?

My code at the moment is as follows:

Private Sub LstDays_AfterUpdate()
    Dim startDate As Date
    Dim endDate As Date
    Dim period As String
    
    period = Me.LstDays
            startDate = DateSerial(Year(Date), Month(Date), Day(Date))
    Select Case period
        Case "Today"
            endDate = DateAdd("d", 1, startDate)
        Case "Yesterday"
            endDate = startDate
            startDate = DateAdd("d", -1, startDate)
        Case "Last 4 Days"
            endDate = startDate
            startDate = DateAdd("d", -4, endDate)
        Case "Last 9 Days"
            endDate = startDate
            startDate = DateAdd("d", -9, endDate)
    End Select
    
    'Purpose:   Build up the criteria string form the non-blank search boxes, and apply to the form's Filter.
    'Notes:     1. We tack " AND " on the end of each condition so you can easily add more search boxes; _
                        we remove the trailing " AND " at the end.
    '           2. The date range works like this: _
                        Both dates      = only dates between (both inclusive. _
                        Start date only = all dates from this one onwards; _
                        End date only   = all dates up to (and including this one).
    Dim strWhere As String                  'The criteria string.
    Dim lngLen As Long                      'Length of the criteria string to append to.
    Const conJetDate = "\#mm\/dd\/yyyy\#"   'The format expected for dates in a JET query string.
    
        'Number field example. Do not add the extra quotes.
    If Not IsNull(Me.LstUser) Then
        strWhere = strWhere & "([User] = " & Me.LstUser & ") AND "
    End If
       
       
    'Date field example. Use the format string to add the # delimiters and get the right international format.
    If Not IsNull(Me.LstDays) Then
        strWhere = strWhere & "([EnteredOn] >= " & Format(startDate, conJetDate) & ") AND "
    End If
    
    '***********************************************************************
    'Chop off the trailing " AND ", and use the string as the form's Filter.
    '***********************************************************************
    'See if the string has more than 5 characters (a trailng " AND ") to remove.
    lngLen = Len(strWhere) - 5
    If lngLen <= 0 Then     'Nah: there was nothing in the string.
        MsgBox "No criteria", vbInformation, "Nothing to do."
    Else                    'Yep: there is something there, so remove the " AND " at the end.
        strWhere = Left$(strWhere, lngLen)
        'For debugging, remove the leading quote on the next line. Prints to Immediate Window (Ctrl+G).
        'Debug.Print strWhere
        
        'Finally, apply the string as the form's Filter.
        Me.Filter = strWhere
        Me.FilterOn = True
    End If
End Sub