Lotus Notes Email (1 Viewer)

[Len Boorman]

Simply put I have a report that I want to email as an attachment via Lotus Notes.

Have tried using Tools/Office Links/Publish with Word but the "graphic" bits get lost. This is a report I want the recipient to print and fill in missing bits. In the report the "blank" field has a border around the field and this gets lost using Tools/Office Links.

Have searched forum and there are lots of postings but they are all a bit over my head. Is there someone who is willing to give me some simple instructions.

Thanks

Len B

 

[wh00t]

here's the code that I use to do it

Public Function SendNotesMail(strSendTo As String, strBody As String, strSubject As String)
'This public sub will send a mail and attachment if neccessary to the recipient including the body text.
'Requires that notes client is installed on the system.

'Set up the objects required for Automation into lotus notes

DoCmd.OutputTo acOutputReport, "ReportName", acFormatXLS, "C:\Mail.xls", False

Dim Subject As String
Dim Attachment As String
Dim Recipient As String
Dim BodyText As String
Dim SaveIt As Boolean
Dim Maildb As Object 'The mail database
Dim UserName As String 'The current users notes name
Dim MailDbName As String 'THe current users notes mail database name
Dim MailDoc As Object 'The mail document itself
Dim AttachME As Object 'The attachment richtextfile object
Dim Session As Object 'The notes session
Dim EmbedObj As Object 'The embedded object (Attachment)
Dim EmailSend As Object
Dim EmailApp As Object

'Start a session to notes

Set Session = CreateObject("Notes.NotesSession")

'Get the sessions username and then calculate the mail file name.
'You may or may not need this as for MailDBname with some systems you can pass an empty string
UserName = Session.UserName
MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf"

'Open the mail database in notes
Set Maildb = Session.GetDatabase("", MailDbName)
If Maildb.IsOpen = True Then
'Already open for mail
Else
Maildb.OPENMAIL
End If

'Set up the new mail document
Set MailDoc = Maildb.CreateDocument
MailDoc.Form = "Memo"
MailDoc.sendto = strSendTo
MailDoc.Subject = strSubject
MailDoc.Body = strBody
MailDoc.SaveMessageOnSend = SaveIt

'Set up the embedded object and attachment and attach it

'If Attachment <> "" Then
Set AttachME = MailDoc.CreateRichTextItem("C:\Mail.xls")
Set EmbedObj = AttachME.EmbedObject(1454, "", "C:\Mail.xls")
'End If

'Send the document
MailDoc.Send 0, Recipient

'Clean Up
Set Maildb = Nothing
Set MailDoc = Nothing
Set AttachME = Nothing
Set Session = Nothing
Set EmbedObj = Nothing
Kill ("C:\Mail.xls")

End Function

paste the above code in a module

then place the following line of code in the event that you would like to send the mail (e.g. in the OnClick event for a button)

SendNotesMail "email@email.com", "Body Message", "Subject"



this code creates an excel spreadsheet from the report and attaches it to the notes e-mail, sends the e-mail then deletes the created excel document

 

[Len Boorman]

Thanks for the reply. Have taken a copy of everything you said. Am trying an alternative using Acrobat at present.
Much appreciate your interest

Len B